::: 델파이 Tip&Trick :::

델파이 Tip&Trick 성격에 맞지 않는 광고,비방,질문의 글은 즉시 삭제하며
내용을 복사하여 사용할 경우 반드시 이곳(http://www.howto.pe.kr)을 출처로 명시하여 주세요


Category

  김영대(2004-11-06 17:23:00, Hit : 5473, Vote : 1266
 http://www.howto.pe.kr
 네트워크 공유 설정/공유 사용 권한/해제 하기 (Windows NT/2000)

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

const
  MB_ERR_INVALID_CHARS = $00000008;
  ACL_REVISION = 2;
  
type
  // Windows 9x는 문자열을 ANSI로 사용하지만 Windows NT이상은 Unicode로 사용한다
  // Windows 9x에서 주로 SHARE_INFO_50 을 사용하지만 Windows NT 이상에서는 주로 SHARE_INFO_2를 사용한다
  // 특히 Windows NT 이상에서 공유사용권한을 주려면 SHARE_INFO_502를 사용해야 한다
  // Windows 9x는 Svrapi.dll에 의해 Windows NT는 Netapi32.dll 에 의해 서비스 받는다
  share_info_502 = packed record
    shi502_netname        : PWideChar;
    shi502_type           : DWORD;
    shi502_remark         : PWideChar;
    shi502_permissions    : DWORD;
    shi502_max_uses       : DWORD;
    shi502_current_uses   : DWORD;
    shi502_path           : PWideChar;
    shi502_passwd         : PWideChar;
    shi502_reserved       : DWORD;
    shi502_security_descriptor: PSECURITY_DESCRIPTOR ;
  end;
  pshare_info_502 = ^share_info_502;

var
  Form1: TForm1;

implementation
{$R *.DFM}

function NetShareAdd(ServerName: PWideChar;
                     ShareLevel: SmallInt;
                     Buffer: Pointer;
                     Error: PLongword): Integer; stdcall; external 'Netapi32.DLL';

function NetShareDel(ServerName: PWideChar;
                     NetName: PWideChar;
                     Reserved: Word): Integer; stdcall; external 'Netapi32.DLL';

procedure AddAccountNameToAcl(ptr_acl: PACL; AccountName: String; Access_Mask: DWORD);
var
  SidBuffer: array[1..100] of byte;
  ptr_sid: PSID;
  SidBufSz: dword;
  DomainNameBuf: String;
  DomainNameBufSz: dword;
  SNU: Sid_Name_Use;
begin
  ptr_sid  := @SidBuffer;
  SidBufSz := SizeOf(SidBuffer);
  SetLength(DomainNameBuf, 256);
  DomainNameBufSz := 256;

  // 사용자명 또는 그룹명이 시스템에 있는지 검사
  if not LookupAccountName(nil, PChar(AccountName), ptr_sid, SidBufSz,
                           PChar(DomainNameBuf), DomainNameBufSz, SNU) then
    ShowMessage('사용자 또는 그룹명이 없습니다: '+AccountName);

  SetLength(DomainNameBuf, DomainNameBufSz);
  
  // 사용자 또는 그룹에 접근 권한주기(모든 권한은 GENERIC_ALL 로 설정)
  Win32Check(AddAccessAllowedAce(ptr_acl^, ACL_REVISION,
                                 Access_Mask,
                                 ptr_sid));
end;
                    
function ShareResource(sServerName: String;
                       sNetName: String;
                       ShareType: DWORD;
                       sRemark: String;
                       Permission: DWORD;
                       Max_uses: DWORD;
                       Current_uses: DWORD;
                       sFilePath: String;
                       sPasswd: String): Integer;
var
  MyShare: share_info_502;
  PMyShare: pshare_info_502;
  bServerName, bNetName, bRemark, bFilePath, bPasswd: PWideChar;
  parm_err: DWORD;

  SD: TSecurityDescriptor;
  SA: TSecurityAttributes;
  SI: SECURITY_INFORMATION;
  AclBuf: array[1..1024] of byte;
  ptr_acl: PACL;  
begin
  try
    // 유니코드를 저장할 버퍼(double-byte)
    bServerName := GlobalAllocPtr(GHND, (length(sServerName)*2)+2);
    if bServerName = nil then
      raise Exception.Create('Out of memory');
    sServerName := UpperCase(sServerName);
    // 유니코드로 변환
    MultiByteToWideChar(CP_ACP, MB_ERR_INVALID_CHARS,
                        pchar(sServerName), length(sServerName),
                        bServerName, (length(sServerName)*2)+2);
                            
    bNetName := GlobalAllocPtr(GHND, (length(sNetName)*2)+2);
    if bNetName = nil then
      raise Exception.Create('Out of memory');
    sNetName := UpperCase(sNetName);
    MultiByteToWideChar(CP_ACP, MB_ERR_INVALID_CHARS,
                        pchar(sNetName), length(sNetName),
                        bNetName, (length(sNetName)*2)+2);

    bRemark := GlobalAllocPtr(GHND, (length(sRemark)*2)+2);
    if bRemark = nil then
      raise Exception.Create('Out of memory');
    MultiByteToWideChar(CP_ACP, MB_ERR_INVALID_CHARS,
                        pchar(sRemark), length(sRemark),
                        bRemark, (length(sRemark)*2)+2);

    bFilePath := GlobalAllocPtr(GHND, (length(sFilePath)*2)+2);
    if bFilePath = nil then
      raise Exception.Create('Out of memory');
    sFilePath := UpperCase(sFilePath);
    MultiByteToWideChar(CP_ACP, MB_ERR_INVALID_CHARS,
                        pchar(sFilePath), length(sFilePath),
                        bFilePath, (length(sFilePath)*2)+2);

    bPasswd := GlobalAllocPtr(GHND, (length(sPasswd)*2)+2);
    if bPasswd = nil then
      raise Exception.Create('Out of memory');
    MultiByteToWideChar(CP_ACP, MB_ERR_INVALID_CHARS,
                        pchar(sPasswd), length(sPasswd),
                        bPasswd, (length(sPasswd)*2)+2);

    // 권한 설정                        
    Win32Check(InitializeSecurityDescriptor(@SD, SECURITY_DESCRIPTOR_REVISION));
    ptr_acl:= @AclBuf;
    Win32Check(InitializeACL(ptr_acl^, SizeOf(AclBuf), ACL_REVISION));

    // 폴더에 권한을 줄 사용자 또는 그룹을 지정한다
    AddAccountNameToAcl(ptr_acl, 'everyone',    SPECIFIC_RIGHTS_ALL or GENERIC_READ); // 읽기
    AddAccountNameToAcl(ptr_acl, 'Power Users', SPECIFIC_RIGHTS_ALL or GENERIC_ALL);  // 모든 권한
    Win32Check(SetSecurityDescriptorDacl(@SD, true, ptr_acl, false));

    // 공유 설정
    MyShare.shi502_netname      := bNetName;
    MyShare.shi502_type         := ShareType;
    MyShare.shi502_remark       := bRemark;
    MyShare.shi502_permissions  := Permission; // not support share-level security in Windows NT or higher
    MyShare.shi502_max_uses     := Max_uses;
    MyShare.shi502_current_uses := Current_uses;
    MyShare.shi502_path         := bFilePath;
    MyShare.shi502_passwd       := bPasswd;
    MyShare.shi502_security_descriptor := @SD;
    PMyShare := @MyShare;
    Result := NetShareAdd(bServerName, 502, PMyShare, @parm_err);

  finally
    if bServerName <> nil then
      GlobalFreePtr(bServerName);
    if bNetName <> nil then
      GlobalFreePtr(bNetName);
    if bRemark <> nil then
      GlobalFreePtr(bRemark);
    if bFilePath <> nil then
      GlobalFreePtr(bFilePath);
    if bPasswd <> nil then
      GlobalFreePtr(bPasswd);

    LocalFree(Cardinal(ptr_acl));      
  end;
end;  

function DeleteShare(sServerName: String; sNetName: String): Integer;
var
  bServerName, bNetName: PWideChar;
begin
  try
    // 유니코드를 저장할 버퍼(double-byte)
    bServerName := GlobalAllocPtr(GHND, (length(sServerName)*2)+2);
    if bServerName = nil then
      raise Exception.Create('Out of memory');
    sServerName := UpperCase(sServerName);
    // 유니코드로 변환
    MultiByteToWideChar(CP_ACP, MB_ERR_INVALID_CHARS,
                        pchar(sServerName), length(sServerName),
                        bServerName, (length(sServerName)*2)+2);
                            
    bNetName := GlobalAllocPtr(GHND, (length(sNetName)*2)+2);
    if bNetName = nil then
      raise Exception.Create('Out of memory');
    sNetName := UpperCase(sNetName);
    MultiByteToWideChar(CP_ACP, MB_ERR_INVALID_CHARS,
                        pchar(sNetName), length(sNetName),
                        bNetName, (length(sNetName)*2)+2);

    // 공유 해제
    Result := NetShareDel(bServerName, bNetName, 0);
  finally
    if bServerName <> nil then
      GlobalFreePtr(bServerName);
    if bNetName <> nil then
      GlobalFreePtr(bNetName);
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  rt: Integer;
begin
  rt := ShareResource('' ,         // 컴퓨터 이름 (nil 은 Local Machine을 의미합니다)
                      'ShareZZZ',  // 공유이름
                      0,           // 0=Disk drive, 1=Print queue
                      '공유예제',  // 설명
                      0,           // 권한
                      4,           // 사용자 제한(최대한 허용은 DWORD(-1))
                      0,           //
                      'C:\ZZZ',    // 공유할 폴더명 (전부 대문자로 지정)
                      '1111');     // 암호
  if rt = 0 then
    ShowMessage('폴더가 공유되었습니다')
  else
    ShowMessage('폴더를 공유할 수 없습니다.  에러번호('+IntToStr(rt)+')');
end;

procedure TForm1.Button2Click(Sender: TObject);
var
  rt: Integer;
begin
  rt := DeleteShare('', 'ShareZZZ'); // 컴퓨터 이름(nil 은 Local Machine을 의미)
  if rt = 0 then
    ShowMessage('폴더의 공유를 해제하였습니다')
  else
    ShowMessage('폴더의 공유를 해제할 수 없습니다.  에러번호('+IntToStr(rt)+')');
end;

end.





651   [일반/컴포넌트] RichEdit 에 URL link 만들기  김영대 2004/08/04 5761 1286
650   [일반/컴포넌트] TOpenDialog 의 '선택','취소' 버튼 이름 바꾸기  김영대 2003/03/07 4149 1286
649   [윈도우즈 API] 다른 프로그램의 구동 디렉토리 알아내기  김영대 2003/03/07 4760 1285
648   [윈도우즈 API] Windows Desktop에 직접 그림을 그리고(draw) 지우기(refresh)  김영대 2003/03/04 4567 1285
647   [윈도우즈 API] 윈도우즈 탐색기에서 "Copy" 될 파일목록 구하기  김영대 2003/03/07 4854 1284
646   [시스템] 윈도우즈 화면 잠그기  김영대 2004/08/03 5049 1283
645   [시스템] 절약형 모니터의 켜기/끄기  김영대 2003/03/04 4663 1282
644   [일반/컴포넌트] Access Violation at address ?????? 로부터 소스위치 알기  김영대 2003/03/07 6346 1281
643   [시스템] 파일이 다른 프로그램에 의해 사용중인지 검사  김영대 2003/03/07 5655 1280
642   [일반/컴포넌트] Treeview의 수평 스크롤바 감추고 스크롤 막기  김영대 2006/03/22 5588 1278
641   [네트웍/인터넷] FTP로 특정 파일의 권한(site chmod) 변경하기  김영대 2004/10/09 5592 1278
640   [시스템] 드라이브 포맷(Format) API 함수  김영대 2003/03/04 4706 1278
639   [윈도우즈 API] PrintScreen(PrtSc)키의 동작 막기  김영대 2003/03/07 5695 1277
638   [일반/컴포넌트] 객체의 valid검사 Assigned() 대체  김영대 2005/07/29 4861 1276
637   [COM/OLE] 윈도우즈 "인터넷 등록 정보" 화면  김영대 2004/07/25 4094 1276
636   [시스템] 프로그램에서 화면모드 변경하기  김영대 2003/03/04 4651 1276
635   [일반/컴포넌트] ListView의 타이틀 폰트 바꾸기  김영대 2005/03/31 5334 1274
634   [일반/컴포넌트] MIME 타입에 해당하는 파일 확장자 구하기  김영대 2004/11/18 4764 1274
633   [윈도우즈 API] 전체 화면(Full Screen) 만들기  김영대 2003/03/29 4976 1273
632   [일반/컴포넌트] 명령행 인자(command line argument) 사용하기  김영대 2003/03/05 4650 1273
631   [일반/컴포넌트] StringGrid의 Cell에 입력 값 제한 하기  김영대 2003/03/04 5783 1272
630   [시스템] 파일의 소유자와 도메인 구하기2  김영대 2004/09/25 4688 1271
629   [일반/컴포넌트] 해상도(screen resolution)를 변경했는지 검사  김영대 2003/03/07 4465 1271
628   [윈도우즈 API] 4가지 윈도우즈 관련 폴더의 path 구하기  김영대 2003/04/08 5620 1270
627   [윈도우즈 API] Canvas의 색상수  김영대 2003/03/04 4093 1269
626   [COM/OLE] TWebBrowser에서 JavaScript 호출하기2  김영대 2004/10/10 6075 1268
625   [COM/OLE] IE의 속성을 변경하여 뛰우기  김영대 2006/02/28 5418 1266
  [네트웍/인터넷] 네트워크 공유 설정/공유 사용 권한/해제 하기 (Windows NT/2000)  김영대 2004/11/06 5473 1266
623   [COM/OLE] ActiveForm의 OnDestroy 대용  김영대 2005/04/21 5399 1265
622   [시스템] 윈도우즈에 설치된 모든 인증서(certificate) 정보 읽어오기  김영대 2004/10/29 5660 1264
621   [윈도우즈 API] 화면캡처하기 Delphi3.0에서...  김영대 2003/03/04 4688 1264
620   [윈도우즈 API] 떠있는 모든 Microsoft Internet Explorer 죽이기  김영대 2003/03/29 4467 1262
619   [시스템] 한글 한 음절을 초성,중성,종성 음소로 분해하기('김' => 'ㄱ'+'ㅣ'+'ㅁ')  김영대 2004/10/22 7829 1261
618   [일반/컴포넌트] TPanel, TImage 에 Gradient 효과 주기  김영대 2003/03/07 4333 1261
617   [COM/OLE] TWebBroswer 에서 오른쪽 마우스 클릭 막기  김영대 2004/11/24 5056 1260
616   [일반/컴포넌트] 키보드의 Shift+Tab 이 눌린것처럼 처리하기  김영대 2003/04/14 4559 1260
615   [윈도우즈 API] Windows error beep 켜기/끄기  김영대 2003/03/07 4420 1260
614   [데이터베이스] Stored Procedure 작성을 어떻게 하나  김영대 2003/03/04 4884 1260
613   [시스템] 로컬 가상 드라이버(substitution device) 만들고 제거하기  김영대 2004/07/25 5469 1259
612   [일반/컴포넌트] 두개의 RichEdit 사이에 내용 복사하기  김영대 2003/03/06 5359 1259

[1][2][3][4][5][6][7][8] 9 [10]..[25] [다음 10개]
 

Copyright 1999-2019 Zeroboard / skin by zero