::: 델파이 Tip&Trick :::

델파이 Tip&Trick 성격에 맞지 않는 광고,비방,질문의 글은 즉시 삭제하며
내용을 복사하여 사용할 경우 반드시 이곳(http://www.howto.pe.kr)을 출처로 명시하여 주세요


Category

  김영대(2003-03-07 21:04:00, Hit : 4348, Vote : 1047
 두 StringGrid 의 scroll 을 동기화 시키기

// 1.먼저 아래 콤포넌트를 설치한다
unit SyncStringGrid;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  Grids;

type
  TSyncKind = (skBoth, skVScroll, skHScroll);
  TSyncStringGrid = class(TStringGrid)
  private
    FInSync: Boolean;
    FsyncGrid: TSyncStringGrid;
    FSyncKind: TSyncKind;
    { Private declarations }

    procedure WMVScroll( Var Msg: TMessage ); message WM_VSCROLL;
    procedure WMHScroll( Var Msg: TMessage ); message WM_HSCROLL;
  protected
    { Protected declarations }
  public
    { Public declarations }
    procedure DoSync( msg, wparam: Integer; lparam: longint ); virtual;
  published
    { Published declarations }
    property SyncGrid: TSyncStringGrid read FSyncGrid write FSyncGrid;
    property SyncKind: TSyncKind read FSyncKind write FSyncKind default skBoth;
  end;

procedure Register;

implementation

procedure Register;
begin
  RegisterComponents('Samples', [TSyncStringGrid]);
end;

procedure TSyncStringGrid.WMVScroll( Var Msg: TMessage );
Begin
  If not FInSync and
     Assigned( FSyncGrid ) and
     (FSyncKind In [skBoth, skVScroll])
  Then
    FSyncGrid.DoSync( WM_VSCROLL, msg.wparam, msg.lparam );
  inherited;
end;

procedure TSyncStringGrid.WMHScroll( Var Msg: TMessage );
Begin
  If not FInSync and
     Assigned( FSyncGrid ) and
     (FSyncKind In [skBoth, skHScroll])
  Then
    FSyncGrid.DoSync( WM_HSCROLL, msg.wparam, msg.lparam );
  inherited;
end;

procedure TSyncStringGrid.DoSync( msg, wparam: Integer; lparam: longint );
begin
  FInSync := True;
  Perform( msg, wparam, lparam );
  FinSync := False;
end;

end.



// 2.아래 예제를 실행하여 두 그리드의 scroll을 움직여 본다
unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  Grids, SyncStringGrid;

type
  TForm1 = class(TForm)
    SyncStringGrid1: TSyncStringGrid;
    SyncStringGrid2: TSyncStringGrid;
    procedure FormActivate(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation
{$R *.DFM}

procedure TForm1.FormActivate(Sender: TObject);
var
  i, j: Integer;
begin
  // StringGrid1의 크기와 값을 임의로 지정한다(예제용)
  SyncStringGrid1.ColCount := 15;
  SyncStringGrid1.RowCount := 20;
  for i := 1 to SyncStringGrid1.ColCount - 1 do
   SyncStringGrid1.Cells[i, 0] := Char(Ord('A')+i-1);
  for i := 1 to SyncStringGrid1.RowCount - 1 do
   SyncStringGrid1.Cells[0, i] := IntToStr(i);;
  for i := 1 to SyncStringGrid1.ColCount - 1 do
    for j := 1 to SyncStringGrid1.RowCount - 1 do
      SyncStringGrid1.Cells[i, j] := Format('%.0n', [i * j * 10000.0]);

  // StringGrid2를 StringGrid1과 동일하게
  SyncStringGrid2.ColCount := SyncStringGrid1.ColCount;
  SyncStringGrid2.RowCount := SyncStringGrid1.RowCount;
  for i := 1 to SyncStringGrid1.ColCount - 1 do
    for j := 1 to SyncStringGrid1.RowCount - 1 do
      SyncStringGrid2.Cells[i, j] := SyncStringGrid1.Cells[i, j];

  // 두 그리드의 scroll 을 동기화 시키도록 상호 지정한다
  SyncStringGrid1.SyncGrid := SyncStringGrid2;
  SyncStringGrid2.SyncGrid := SyncStringGrid1;
end;

end.





651   [일반/컴포넌트] 투명한(Transparent) TPanel 콤포넌트  김영대 2003/03/07 4922 1152
650   [데이터베이스] 테이블,인덱스 복사하기  김영대 2003/03/07 3931 1123
649   [일반/컴포넌트] TRichEdit 에 윗첨자, 아랫첨자 만들기  김영대 2003/03/07 4369 1120
648   [윈도우즈 API] 외부 프로그램의 크기를 내 프로그램에서 변경하기  김영대 2003/03/07 4429 1155
647   [윈도우즈 API] Ctrl-Esc, Ctrl-Alt-Del, Alt-Tab 입력 막기  김영대 2003/03/07 5611 1229
646   [일반/컴포넌트] 달력에 그림이나 기호 그리기  김영대 2003/03/07 4261 1000
645   [윈도우즈 API] 파일의 이동,복사,삭제 API  김영대 2003/03/07 6436 1546
644   [일반/컴포넌트] TPanel, TImage 에 Gradient 효과 주기  김영대 2003/03/07 4379 1266
643   [시스템] System, User, GDI Resource  김영대 2003/03/07 4628 1338
642   [시스템] PC에 설치된 드라이브 목록 구하기  김영대 2003/03/07 4562 1111
641   [윈도우즈 API] PrintScreen(PrtSc)키의 동작 막기  김영대 2003/03/07 5761 1286
640   [시스템] 플로피(floppy) 디스크 드라이브의 타입 구하기  김영대 2003/03/07 5866 1534
639   [일반/컴포넌트] 문자열 프로시저명으로 실제 프로시저 호출하기  김영대 2003/03/07 4882 1534
638   [일반/컴포넌트] StringGrid 수직 스크롤바의 크기를 임의로 바꾸기  김영대 2003/03/07 5044 1071
637   [일반/컴포넌트] JPEG, Bitmap 상호 변환하여 파일로 저장하기  김영대 2003/03/07 4212 1208
636   [일반/컴포넌트] Access Violation at address ?????? 로부터 소스위치 알기  김영대 2003/03/07 6603 1284
635   [일반/컴포넌트] 각도에 따라 회전한 화살표 그리기  김영대 2003/03/07 4331 1084
634   [윈도우즈 API] 작업표시줄의 "항상 위" 검사하여 설정하기  김영대 2003/03/07 4661 1185
633   [윈도우즈 API] 윈도우즈 탐색기에서 "Copy" 될 파일목록 구하기  김영대 2003/03/07 4882 1286
632   [일반/컴포넌트] TStringGrid의 마우스가 있는 Cell의 Hint 표시  김영대 2003/03/07 6543 1676
631   [윈도우즈 API] 윈도우즈 "시작" 메뉴 표시하기/감추기  김영대 2003/03/07 4406 1164
630   [일반/컴포넌트] ListBox의 Item을 버튼으로 계속 삭제하기  김영대 2003/03/07 3968 1082
629   [윈도우즈 API] 윈도우즈의 주소록(WAB) 프로그램 띄우기  김영대 2003/03/07 5366 1717
628   [윈도우즈 API] 다른 프로그램의 구동 디렉토리 알아내기  김영대 2003/03/07 4785 1287
627   [윈도우즈 API] 윈도우즈 전화걸기 화면 띄우기  김영대 2003/03/07 4507 1196
626   [일반/컴포넌트] RichEdit에서 HTML 태그를 다른색으로 표시하기  김영대 2003/03/07 5389 1191
625   [윈도우즈 API] DDE를 사용하여 IE, Netscape의 현재 URL 가져오기  김영대 2003/03/07 4522 1220
624   [윈도우즈 API] 데스크탑에 있는 아이콘의 갯수 구하기  김영대 2003/03/07 4142 1125
623   [일반/컴포넌트] design mode 인지 검사하기  김영대 2003/03/07 5649 1434
622   [네트웍/인터넷] 프린터의 용지 크기/공급 설정하기  김영대 2003/03/07 6750 1238
621   [시스템] 프린터의 "용지 공급" 리스트 구하기  김영대 2003/03/07 4647 1328
620   [네트웍/인터넷] Read/Write to COM Port  김영대 2003/03/07 4760 1125
619   [일반/컴포넌트] Button의 Mouse Down/Up 흉내내기  김영대 2003/03/07 4315 1108
  [일반/컴포넌트] 두 StringGrid 의 scroll 을 동기화 시키기  김영대 2003/03/07 4348 1047
617   [일반/컴포넌트] 해상도(screen resolution)를 변경했는지 검사  김영대 2003/03/07 4525 1274
616   [일반/컴포넌트] StringGrid의 선택된 Cell을 버튼으로 보이기  김영대 2003/03/07 4346 1073
615   [윈도우즈 API] Windows NT 도메인명 가져오기  김영대 2003/03/07 5598 1464
614   [시스템] Locking/ Unlocking floppy driver or CD  김영대 2003/03/07 4131 1159
613   [시스템] CD-ROM의 변경여부를 감시하기  김영대 2003/03/07 4867 1255
612   [윈도우즈 API] 즐겨찾기 폴더의 파일에서 URL 뽑아내기  김영대 2003/03/07 5095 1236

[1][2][3][4][5][6][7][8] 9 [10]..[25] [다음 10개]
 

Copyright 1999-2020 Zeroboard / skin by zero