::: 델파이 Tip&Trick :::

델파이 Tip&Trick 성격에 맞지 않는 광고,비방,질문의 글은 즉시 삭제하며
내용을 복사하여 사용할 경우 반드시 이곳(http://www.howto.pe.kr)을 출처로 명시하여 주세요


Category

  김영대(2004-08-26 15:05:52, Hit : 5470, Vote : 1235
 http://www.howto.pe.kr
 윈도우즈 Registry 변경여부 감시하기

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, Registry, syncobjs;

const
  WM_REGNOTIFY  = WM_USER + 1;

type
  TForm1 = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure FormClose(Sender: TObject; var Action: TCloseAction);
  private
    { Private declarations }
  public
    { Public declarations }
    procedure Process_REGNOTIFY(var Msg: TMessage); message WM_REGNOTIFY;
  end;

type
  TRegNotifyThread = class(TThread)
  private
    FReg: TRegistry;
    FEvent: Cardinal;

    FRootKey: HKey;
    FKey: String;
    FWatchSub: Boolean;
    FFilter: Integer;
    FWnd: THandle;
    FMsg: Cardinal;
  public
    constructor Create(RootKey: HKey;
                       Key: String;
                       WatchSub: Boolean;
                       Filter: Integer;
                       Wnd: THandle;
                       Msg: Cardinal);
    procedure Execute; override;
    destructor Destroy; override;
  end;
  
var
  Form1: TForm1;
  thr_reg: TRegNotifyThread;

implementation

{$R *.dfm}

constructor TRegNotifyThread.Create(RootKey: HKey;
                                    Key: String;
                                    WatchSub: Boolean;
                                    Filter: Integer;
                                    Wnd: THandle;
                                    Msg: Cardinal);
begin
  // thread object의 instance를 생성한다
  // Create의 파라미터가 False이면 thread를 생성한후 즉시 Execute를 호출하여 실행한다
  //            "        True이면 Resume을 호출하기 전까지 실행하지 않는다(suspended)
  inherited Create(True);

  FRootKey  := RootKey;
  FKey      := Key;
  FWatchSub := WatchSub;
  FFilter   := Filter;
  FWnd      := Wnd;
  FMsg      := Msg;

  FReg := TRegistry.Create;
  FReg.RootKey := RootKey;
  if not FReg.OpenKey(FKey, False) then
  begin
    raise Exception.Create('Can''t not open registry key ' + FKey);
  end;
  FEvent := CreateEvent(nil, False, False, 'RegNotify');
  RegNotifyChangeKeyValue(FReg.CurrentKey, FWatchSub, FFilter, FEvent, True);
  
  // thread의 실행이 종료하면 자동으로 free되게 설정
  FreeOnTerminate := True;

  // 실행이 일시 중지된(suspended) thread를 실행한다
  Resume;
end;

destructor TRegNotifyThread.Destroy;
begin
  CloseHandle(FEvent);
  FReg.Free;
  inherited;
end;

procedure TRegNotifyThread.Execute;
begin
  while not Terminated do
  begin
    if WaitForSingleObject(FEvent, INFINITE) = WAIT_OBJECT_0 then
    begin
      SendMessage(FWnd, FMsg, FRootKey, LongInt(PChar(FKey)));
      // ResetEvent(FEvent); // 수동 리셋일때
      RegNotifyChangeKeyValue(FReg.CurrentKey, FWatchSub, FFilter, FEvent, True); // 재등록
    end;
  end;
end;

procedure TForm1.Process_REGNOTIFY(var Msg: TMessage);
begin
  inherited;

  ShowMessage(PChar(Msg.lParam));
  
  Msg.Result := 0;
end;

procedure TForm1.FormCreate(Sender: TObject);
const
  Filter =
    REG_NOTIFY_CHANGE_NAME or
    REG_NOTIFY_CHANGE_ATTRIBUTES or
    REG_NOTIFY_CHANGE_LAST_SET or
    REG_NOTIFY_CHANGE_SECURITY; // REG_LEGAL_CHANGE_FILTER 는 모든 변경값
begin
  Button1Click(Sender);

  {thread instance 생성}
  thr_reg := TRegNotifyThread.Create(HKEY_LOCAL_MACHINE, // 검사할 루트키
                                     PChar('Software\Test'), // 검사할 키
                                     True, // 하위검사
                                     Filter, // 검사할 종류
                                     Self.Handle, // 변경시 메시지를 받을 핸들
                                     WM_REGNOTIFY); // 변경시 받을 메시지
end;

procedure TForm1.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  if Assigned(thr_reg) then
    thr_reg.Terminate;
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  Reg : TRegIniFile;
begin
  Reg := TRegIniFile.Create;
  with reg do
  try
    RootKey := HKEY_LOCAL_MACHINE;
    WriteString('Software\Test',
                'ident',
                IntToStr(Button1.Tag));
    Button1.Tag := Button1.Tag + 1; // 버튼 클릭시마다 변경하기 위하여...          
  finally
    free;
  end;
end;

end.





891   [COM/OLE] 떠있는 모든 Internet Explorer 를 강제 Refresh 시키기  김영대 2004/09/20 4778 1228
890   [일반/컴포넌트] 개행문자를 인식하여 출력하는 StringGrid 예제  김영대 2004/09/18 4928 1081
889   [알고리즘] String ELF Hash 함수  김영대 2004/09/17 4432 1131
888   [알고리즘] String Hash 함수  김영대 2004/09/17 4358 1146
887   [알고리즘] 32bit CRC (cyclic redundancy check)  김영대 2004/09/17 4637 1124
886   [시스템] 실행중인 모든 프로세스의 "CPU 시간"/시작 시간 구하기  김영대 2004/09/15 5782 1297
885   [시스템] 실행중인 모든 프로세스의 "메모리 사용" 구하기  김영대 2004/09/15 6081 1394
884   [시스템] 프로세스가 사용하는 모듈(DLL) 리스트 구하기  김영대 2004/09/15 5633 1232
883   [일반/컴포넌트] PageControl 에서 미리 이동하려는 Sheet 알아내어 제어하기  김영대 2004/09/13 4664 1183
882   [일반/컴포넌트] 다른 윈도우의 PageControl(TabControl) 상태 알아내기  김영대 2004/09/13 4720 1295
881   [일반/컴포넌트] StringGrid 를 텍스트파일(csv)로 저장하고 불러오기  김영대 2004/09/11 5248 1134
880   [윈도우즈 API] 표준 콤포넌트에 사용자정의 Property 만들기  김영대 2004/09/10 4422 1164
879   [윈도우즈 API] 다른 프로그램에 마우스/키보드 이벤트 발생시키기  김영대 2004/09/07 7943 1294
878   [일반/컴포넌트] TStringGrid 의 모든 행에 행선택 CheckBox 두기  김영대 2004/09/06 5075 1063
877   [시스템] 조합중인 한글 얻기  김영대 2004/09/06 5897 1314
876   [시스템] IME 입력 시스템 정보  김영대 2004/09/06 6013 1658
875   [일반/컴포넌트] 실행시 StringGrid 에 ComboBox 올리기  김영대 2004/09/04 5875 1035
874   [알고리즘] 두 문자열의 유사도 검사하기  김영대 2004/09/04 4958 1117
873   [일반/컴포넌트] TRichEdit 를 disable 할 때 배경색과 폰트 바꾸기  김영대 2004/09/02 6098 1751
872   [일반/컴포넌트] 문자가 영문/숫자/영숫자/한글 인지 검사하기  김영대 2004/08/31 6796 1473
871   [알고리즘] 문자열에서 순방향/역방향 단어 찾기  김영대 2004/08/31 3964 1034
870   [일반/컴포넌트] TEdit 의 입력시 소/대문자 강제 변환  김영대 2004/08/30 4452 1089
869   [일반/컴포넌트] TListBox 에 여러개의 컬럼 두기  김영대 2004/08/30 4160 1050
868   [시스템] 윈도우즈 재시작  김영대 2004/08/30 4374 1118
867   [윈도우즈 API] 윈도우즈 시작의 "실행" 화면 띄우기2  김영대 2004/08/30 4241 1181
  [시스템] 윈도우즈 Registry 변경여부 감시하기  김영대 2004/08/26 5470 1235
865   [윈도우즈 API] 아이콘 변경 화면 띄우기  김영대 2004/08/26 4289 1146
864   [일반/컴포넌트] little/big endian 변환 함수  김영대 2004/08/25 5533 1469
863   [일반/컴포넌트] 파일을 클립보드로 복사하기  김영대 2004/08/25 4063 1008
862   [일반/컴포넌트] 절대경로와 상대경로 결합  김영대 2004/08/25 4892 1378
861   [윈도우즈 API] '알려진 파일 형식의 파일 확장명 숨김' 여부  김영대 2004/08/25 4788 1197
860   [윈도우즈 API] Active Desktop 활성화 여부  김영대 2004/08/25 4446 1162
859   [시스템] NTFS 파일 시스템 사용 여부  김영대 2004/08/25 5023 1317
858   [네트웍/인터넷] 공유기(NAT,마스커레이딩)사용시 Public IP 구하기  김영대 2004/08/18 6086 1220
857   [COM/OLE] 현재 IE 의 HTML 소스 코드 읽어오기  김영대 2004/08/18 5597 1310
856   [네트웍/인터넷] 스팸(spam) IP 인지 검사하기  김영대 2004/08/17 4805 1204
855   [시스템] 프로세스에 할당된 memory page 구하기  김영대 2004/08/17 4708 1249
854   [일반/컴포넌트] 숫자만 입력받는 TEdit 만들기  김영대 2004/08/17 4529 1222
853   [일반/컴포넌트] INI file 에서 section 단위로 읽기  김영대 2004/08/17 4470 1099
852   [일반/컴포넌트] 실행파일에서 잃어버린 DFM 파일 뽑아내기  김영대 2004/08/17 4992 1324

[1][2] 3 [4][5][6][7][8][9][10]..[25] [다음 10개]
 

Copyright 1999-2019 Zeroboard / skin by zero