::: 델파이 Tip&Trick :::

델파이 Tip&Trick 성격에 맞지 않는 광고,비방,질문의 글은 즉시 삭제하며
내용을 복사하여 사용할 경우 반드시 이곳(http://www.howto.pe.kr)을 출처로 명시하여 주세요


Category

  김영대(2004-08-09 20:04:11, Hit : 4711, Vote : 1207
 http://www.howto.pe.kr
 도넛(Doughnut) 모양의 폼 만들기

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, Buttons;

type
  TForm1 = class(TForm)
    Button1: TButton;
    procedure FormCreate(Sender: TObject);
    procedure FormPaint(Sender: TObject);
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
    rTitleBar : THandle;
    Center    : TPoint;
    CapY      : Integer;
    Circum    : Double;
    SB1       : TSpeedButton;
    RL, RR    : Double;
    procedure TitleBar(Act : Boolean);
    procedure WMNCHITTEST(var Msg: TWMNCHitTest);
      message WM_NCHITTEST;
    procedure WMNCACTIVATE(var Msg: TWMNCACTIVATE);
      message WM_NCACTIVATE;
    procedure WMSetText(var Msg: TWMSetText);
      message WM_SETTEXT;

  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

CONST
  TitlColors : ARRAY[Boolean] OF TColor =
    (clInactiveCaption, clActiveCaption);
  TxtColors : ARRAY[Boolean] OF TColor =
    (clInactiveCaptionText, clCaptionText);

procedure TForm1.FormCreate(Sender: TObject);
VAR
  rTemp, rTemp2    : THandle;
  Vertices : ARRAY[0..2] OF TPoint;
  X, Y     : INteger;
begin
  Caption := 'OOOH! Doughnuts!';
  BorderStyle := bsNone; {required}
  IF Width > Height THEN Width := Height
  ELSE Height := Width;  {harder to calc if width <> height}
  Center  := Point(Width DIV 2, Height DIV 2);
  CapY := GetSystemMetrics(SM_CYCAPTION)+8;
  rTemp := CreateEllipticRgn(0, 0, Width, Height);
  rTemp2 := CreateEllipticRgn((Width DIV 4), (Height DIV 4),
    3*(Width DIV 4), 3*(Height DIV 4));
  CombineRgn(rTemp, rTemp, rTemp2, RGN_DIFF);
  SetWindowRgn(Handle, rTemp, True);
  DeleteObject(rTemp2);
  rTitleBar  := CreateEllipticRgn(4, 4, Width-4, Height-4);
  rTemp := CreateEllipticRgn(CapY, CapY, Width-CapY, Height-CapY);
  CombineRgn(rTitleBar, rTitleBar, rTemp, RGN_DIFF);
  Vertices[0] := Point(0,0);
  Vertices[1] := Point(Width, 0);
  Vertices[2] := Point(Width DIV 2, Height DIV 2);
  rTemp := CreatePolygonRgn(Vertices, 3, ALTERNATE);
  CombineRgn(rTitleBar, rTitleBar, rTemp, RGN_AND);
  DeleteObject(rTemp);
  RL := ArcTan(Width / Height);
  RR := -RL + (22 / Center.X);
  X := Center.X-Round((Center.X-1-(CapY DIV 2))*Sin(RR));
  Y := Center.Y-Round((Center.Y-1-(CapY DIV 2))*Cos(RR));
  SB1 := TSpeedButton.Create(Self);
  WITH SB1 DO
    BEGIN
      Parent     := Self;
      Left       := X;
      Top        := Y;
      Width      := 14;
      Height     := 14;
      OnClick    := Button1Click;
      Caption    := 'X';
      Font.Style := [fsBold];
    END;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  Close;
End;

procedure TForm1.WMNCHITTEST(var Msg: TWMNCHitTest);
begin
  Inherited;
  WITH Msg DO
    WITH ScreenToClient(Point(XPos,YPos)) DO
      IF PtInRegion(rTitleBar, X, Y) AND
       (NOT PtInRect(SB1.BoundsRect, Point(X,Y))) THEN
          Result := htCaption;
end;

procedure TForm1.WMNCActivate(var Msg: TWMncActivate);
begin
  Inherited;
  TitleBar(Msg.Active);
end;

procedure TForm1.WMSetText(var Msg: TWMSetText);
begin
  Inherited;
  TitleBar(Active);
end;

procedure TForm1.TitleBar(Act: Boolean);
VAR
  TF      : TLogFont;
  R       : Double;
  N, X, Y : Integer;
begin
  IF Center.X = 0 THEN Exit;
  WITH Canvas DO
    begin
      Brush.Style := bsSolid;
      Brush.Color := TitlColors[Act];
      PaintRgn(Handle, rTitleBar);
      R  := RL;
      Brush.Color := TitlColors[Act];
      Font.Name := 'Arial';
      Font.Size := 12;
      Font.Color := TxtColors[Act];
      Font.Style := [fsBold];
      GetObject(Font.Handle, SizeOf(TLogFont), @TF);
      FOR N := 1 TO Length(Caption) DO
        BEGIN
          X := Center.X-Round((Center.X-6)*Sin(R));
          Y := Center.Y-Round((Center.Y-6)*Cos(R));
          TF.lfEscapement := Round(R * 1800 / pi);
          Font.Handle := CreateFontIndirect(TF);
          TextOut(X, Y, Caption[N]);
          R := R - (((TextWidth(Caption[N]))+2) / Center.X);
          IF R < RR THEN Break;
        END;
      Font.Name := 'MS Sans Serif';
      Font.Size := 8;
      Font.Color := clWindowText;
      Font.Style := [];
    end;
end;

procedure TForm1.FormPaint(Sender: TObject);
begin
  WITH Canvas DO
    BEGIN
      Pen.Color := clBlack;
      Brush.Style := bsClear;
      Pen.Width := 1;
      Pen.Color := clWhite;
      Arc(1, 1, Width-1, Height-1, Width, 0, 0, Height);
      Arc((Width DIV 4)-1, (Height DIV 4)-1,
        3*(Width DIV 4)+1, 3*(Height DIV 4)+1, 0, Height, Width, 0);
      Pen.Color := clBlack;
      Arc(1, 1, Width-1, Height-1, 0, Height, Width, 0);
      Arc((Width DIV 4)-1, (Height DIV 4)-1,
        3*(Width DIV 4)+1, 3*(Height DIV 4)+1, Width, 0, 0, Height);
      TitleBar(Active);
    END;
end;

end.





171   [일반/컴포넌트] 표준 TListBox 에 Radio 버튼 올리기  김영대 2004/07/27 4234 1158
170   [시스템] 실행중인 모든 프로세스의 Domain, User 구하기  김영대 2004/07/27 5267 1270
169   [일반/컴포넌트] RichEdit 의 마우스 커서 아래의 글자 구하기  김영대 2004/07/27 4757 1108
168   [시스템] Keyboard hook 을 사용한 OnKeyDown 구현  김영대 2004/07/27 5321 1361
167   [일반/컴포넌트] TListBox 의 마우스 커서 아래의 아이템 구하기  김영대 2004/07/27 3929 1057
166   [COM/OLE] 특정 웹페이지의 모든 Link URL 구하기  김영대 2004/07/27 5870 1550
165   [COM/OLE] PDF ActiveX 사용하기  김영대 2004/08/02 5348 1253
164   [COM/OLE] 특정 사이트의 내용을 JPG 로 저장하기  김영대 2004/08/02 5358 1198
163   [COM/OLE] 특정 사이트의 form 을 강제 submit 하기  김영대 2004/08/02 5979 1477
162   [COM/OLE] IE 에 직접 입력한 URL 목록 구하기  김영대 2004/08/02 4542 1121
161   [시스템] 외부 프로그램 종료 시키기  김영대 2004/08/02 6654 1253
160   [시스템] DOS (명령 프롬프트) 창의 색상, 화면 모드 바꾸기  김영대 2004/08/02 5716 1665
159   [일반/컴포넌트] Search and Select  김영대 2004/08/03 5910 1633
158   [일반/컴포넌트] Zlib 를 이용한 압축과 해제  김영대 2004/08/03 5453 1258
157   [시스템] 일정시간 경과 후 윈도우즈 종료하기  김영대 2004/08/03 4718 1166
156   [시스템] DOS 명령어 실행하고 결과 받아오기 (Win2k,XP)  김영대 2004/08/03 5810 1414
155   [시스템] 윈도우즈 화면 잠그기  김영대 2004/08/03 5271 1345
154   [시스템] 윈도우즈 사용자 계정 정보 구하기  김영대 2004/08/03 5433 1445
153   [시스템] 파일의 소유자와 도메인 구하기  김영대 2004/08/04 4355 1207
152   [일반/컴포넌트] Hex Viewer  김영대 2004/08/04 4401 1113
151   [일반/컴포넌트] RichEdit 에 URL link 만들기  김영대 2004/08/04 6038 1403
150   [일반/컴포넌트] 동적으로 생성한 TLabel 마우스로 이동시키기  김영대 2004/08/04 6524 1919
149   [윈도우즈 API] 세로 타이틀바 만들기  김영대 2004/08/04 5197 1404
148   [일반/컴포넌트] TPanel 로 만든 힌트  김영대 2004/08/05 4631 1187
147   [시스템] 윈도우즈 부팅 모드(정상, 안전)  김영대 2004/08/05 4288 1217
146   [일반/컴포넌트] ListView 내용을 파일로 저장하고 불러오기  김영대 2004/08/05 4692 1128
145   [윈도우즈 API] 휴지통이 비어있는지 확인하기  김영대 2004/08/05 4988 1261
144   [일반/컴포넌트] TreeView 의 노드를 볼드(Bold)로 강조하기  김영대 2004/08/05 6016 1739
143   [시스템] 프로그램 제거(Uninstall) 목록 구하기  김영대 2004/08/05 4974 1319
142   [일반/컴포넌트] Adobe Acrobat 이 설치되었는지 검사하기  김영대 2004/08/06 4617 1158
141   [일반/컴포넌트] Shockwave Flash 가 설치되었는지 검사하고 버전정보 읽어오기  김영대 2004/08/06 6105 1550
140   [일반/컴포넌트] Title bar 에 문자 올리기  김영대 2004/08/06 4774 1287
139   [윈도우즈 API] Type Library 목록 구하기  김영대 2004/08/06 4616 1248
138   [일반/컴포넌트] 벽에 들러붙는 자석폼 만들기  김영대 2004/08/06 4795 1208
137   [COM/OLE] Shockwave Flash ActiveX 사용하기 예제  김영대 2004/08/09 5121 1370
136   [일반/컴포넌트] 수식(Expression) 계산기  김영대 2004/08/09 4671 1155
135   [네트웍/인터넷] Ping 소스  김영대 2004/08/09 7069 1300
  [일반/컴포넌트] 도넛(Doughnut) 모양의 폼 만들기  김영대 2004/08/09 4711 1207
133   [시스템] Sleep 중에도 타이머 이벤트 발생시키기  김영대 2004/08/09 5991 1415
132   [윈도우즈 API] IE 임시 인터넷 파일 폴더 비우기2  김영대 2004/08/11 5015 1315

[이전 10개] [1].. 21 [22][23][24][25]
 

Copyright 1999-2022 Zeroboard / skin by zero