::: 델파이 Tip&Trick :::

델파이 Tip&Trick 성격에 맞지 않는 광고,비방,질문의 글은 즉시 삭제하며
내용을 복사하여 사용할 경우 반드시 이곳(http://www.howto.pe.kr)을 출처로 명시하여 주세요


Category

  김영대(2003-03-07 20:57:41, Hit : 6087, Vote : 1168
 베쥬(Bezier) 곡선 그리기2

// Win95/NT4.0 부터 베쥬(Bezier) 곡선을 그릴 수 있는 API가 추가되었습니다
// 그러나, Delphi 의 TCanvas 에서는 지원되지 않습니다
// 물론 API 를 직접 호출하면 사용할 수 있습니다
// 아래 예제는 PolyBezier() API 를 사용해 타원을 그리는 예제입니다
// http://home.t-online.de/home/Robert.Rossmair/ellipse.htm 를 참고해 보세요

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  ExtCtrls;

type
  TForm1 = class(TForm)
    Image1: TImage;
    procedure FormCreate(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation
{$R *.DFM}

{
  Ellipse approximation using N Bezier curves.
  Relative approximation error <= (1-cos(Pi/N))3/(54*(1+cos(Pi/N)))
     "           "         "   < 4.25E-6        for N = 8
  X, Y: Center coordinates
  A, B: Half axis lengths
  Angle: Angle in radians
}
procedure DrawEllipse(DC: hDC; X, Y, A, B, Angle: Double);
type
  TFloatPoint = record
    X, Y: Double;
  end;
const
  N = 8;
  Alpha = Pi/N;
  Beta = 0.26521648984; // = 4*(1-cos(Alpha))/(3*sin(Alpha))
var
  P: array[0..N*3] of TFloatPoint;
  Q: array[0..N*3] of TPoint; // N Bezier curves
  SinA, CosA: Double;
  Temp: Double;
  I, J, K: Integer;
begin
  for I := 0 to N-1 do
  begin
    Temp := I * (2*Alpha);
    CosA := cos(Temp);
    SinA := sin(Temp);
    K := I*3;
    if K = 0
      then J := N*3-1
      else J := K-1;
    P[K].X := A * CosA;
    P[K].Y := B * SinA;
    SinA := Beta * A * SinA;
    CosA := Beta * B * CosA;
    P[J].X := P[K].X + SinA;
    P[J].Y := P[K].Y - CosA;
    P[K+1].X := P[K].X - SinA;
    P[K+1].Y := P[K].Y + CosA;
  end;
  P[N*3] := P[0];
  CosA := cos(Angle);
  SinA := sin(Angle);
  for i := Low(P) to High(P) do // Rotate and translate
  begin
    Q[I].X := Round(P[I].X*CosA - P[I].Y*SinA +X);
    Q[I].Y := Round(P[I].X*SinA + P[I].Y*CosA +Y);
  end;

  // Draw ellipse and fill it using the current pen and brush
  BeginPath(DC);
  PolyBezier(DC, Q, High(Q)+1);
  EndPath(DC);
  StrokeAndFillPath(DC);
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  DrawEllipse(Image1.Canvas.Handle,
              Image1.Width div 2,
              Image1.Height div 2,
              40,
              80,
              20*(Pi/180)); // Angle 20
end;

end.





291   [일반/컴포넌트] StringGrid의 모든 Cell 선택/해제하기  김영대 2004/09/25 4905 1183
290   [시스템] 특정 DLL 의 함수목록을 구해보자.  구창민 2003/03/14 5602 1183
289   [데이터베이스] Paradox 테이블이 깨졌을때...  김영대 2003/03/05 5089 1183
288   [일반/컴포넌트] 문자열의 word 갯수 세기  김영대 2003/03/04 4372 1183
287   [일반/컴포넌트] 타이틀바 클릭시 사용자 팝업메뉴 보이기  김영대 2003/03/07 4927 1182
286   [윈도우즈 API] 어플리케이션의 중복실행 방지  김영대 2003/03/05 4784 1182
285   [일반/컴포넌트] TRichEdit 에 윗첨자, 아랫첨자 만들기  김영대 2003/03/07 4579 1181
284   [윈도우즈 API] How to flush key buffer  김영대 2003/03/07 4469 1181
283   [일반/컴포넌트] MS-OutLook 으로 메시지 보내기  김영대 2003/03/07 5173 1181
282   [시스템] Hint의 폰트 바꾸기  김영대 2003/03/05 4090 1181
281   [일반/컴포넌트] ListBox의 화면에 보여지는 최상위 Item 번호  김영대 2003/03/07 4356 1180
280   [일반/컴포넌트] 문자열의 끝에서부터 검색하는 Pos() 함수  김영대 2003/03/07 5141 1180
279   [일반/컴포넌트] Memo의 입력행수 제한하기  김영대 2003/03/07 4175 1179
278   [윈도우즈 API] bitmap 인쇄하기  김영대 2003/03/05 4560 1179
277   [일반/컴포넌트] TStringGrid 인쇄하기  김영대 2003/03/07 4806 1178
276   [일반/컴포넌트] 쓰레드를 이용한 복수 Query 동시에 열기  김영대 2003/03/05 6480 1178
275   [윈도우즈 API] 바로 직전에 active 되었던 윈도우와 콘트롤 구하기  김영대 2004/07/24 4667 1175
274   [데이터베이스] 몇가지 BDE 환경정보 구하기  김영대 2003/03/07 4449 1175
273   [COM/OLE] How to register an OCX  김영대 2003/03/06 5057 1173
272   [알고리즘] 숫자를 KB, MB, GB 단위로 환산하기  김영대 2003/11/13 5102 1172
271   [시스템] PC에 설치된 드라이브 목록 구하기  김영대 2003/03/07 4781 1172
270     [COM/OLE] [re] PDF ActiveX 사용하기  초보델피 2005/07/18 5328 1171
269   [일반/컴포넌트] ComboBox에 IE의 URL 입력창 같은 근접검색 두기  김영대 2003/03/31 4668 1170
  [일반/컴포넌트] 베쥬(Bezier) 곡선 그리기2  김영대 2003/03/07 6087 1168
267   [일반/컴포넌트] 수직 스크롤이 맨마지막으로 이동했는지 검사  김영대 2003/03/07 3971 1167
266   [시스템] 일정시간 경과 후 윈도우즈 종료하기  김영대 2004/08/03 4720 1166
265   [일반/컴포넌트] 부활절 달걀(easter egg) 문자열 입력받기  김영대 2003/03/07 4835 1166
264   [시스템] 프린터에 escape 코드를 전달하는 방법  김영대 2003/03/06 3958 1166
263   [윈도우즈 API] 데스크탑 아이콘 전부 감추기/보이기  김영대 2003/03/07 3953 1164
262   [일반/컴포넌트] Memo의 커서를 특정 위치로 보낸후 scroll 시키기  김영대 2003/03/05 5053 1164
261   [일반/컴포넌트] 프로그램 종료시 도움말 화면 닫기  김영대 2003/03/05 4256 1163
260   [윈도우즈 API] "문서" 메뉴에 파일을 등록하고 삭제하기  김영대 2003/03/05 4353 1162
259   [일반/컴포넌트] Variant 변수의 Type 알아내기  김영대 2003/03/05 4406 1162
258   [일반/컴포넌트] 표준 콘트롤의 몇가지 한계  김영대 2003/03/05 4351 1162
257   [시스템] Thread 사용하기  김영대 2003/03/07 4254 1160
256   [일반/컴포넌트] 파일에서 특정 Byte 모두 찾기  김영대 2003/03/07 4549 1159
255   [일반/컴포넌트] Adobe Acrobat 이 설치되었는지 검사하기  김영대 2004/08/06 4618 1158
254   [일반/컴포넌트] 표준 TListBox 에 Radio 버튼 올리기  김영대 2004/07/27 4235 1158
253   [일반/컴포넌트] Button의 Mouse Down/Up 흉내내기  김영대 2003/03/07 4508 1157
252   [데이터베이스] SQL실행시의 모래시계를 표시하지 않는 방법  김영대 2003/03/07 4705 1157

[이전 10개] [1]..[11][12][13][14][15][16][17] 18 [19][20]..[25] [다음 10개]
 

Copyright 1999-2022 Zeroboard / skin by zero