::: 델파이 Tip&Trick :::

델파이 Tip&Trick 성격에 맞지 않는 광고,비방,질문의 글은 즉시 삭제하며
내용을 복사하여 사용할 경우 반드시 이곳(http://www.howto.pe.kr)을 출처로 명시하여 주세요


Category

  김영대(2003-03-06 21:53:34, Hit : 3378, Vote : 878
 문자열 수식문장(expression)의 결과 구하기

// 화면의 Edit1의 Text에 sqrt(43.23*12+3.1/1.64) 를 입력하고
// 버튼을 클릭하시면 그 결과를 계산해서 보여줍니다
// 만약 잘못된 수식이면 에러난 문자로 케럿을 이동시킵니다
//
// 소스 출처: http://www.geocities.com/SiliconValley/Hills/9167/index.htm

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, forms, Dialogs,
  StdCtrls;

type
  Tform1 = class(Tform)
    Edit1: TEdit;
    Button1: TButton;
    Label1: TLabel;
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  form1: Tform1;

implementation
{$R *.DFM}

procedure Eval(formula: String;      {Expression to be evaluated}
               var Value: double;    {Return value}
               var ErrPos: Integer); {error position}
const
  Digit: Set of Char = ['0'..'9'];
var
  Posn: Integer;  {Current position in formula}
  CurrChar: Char; {character at Posn in formula}

  procedure ParseNext;
  begin
    repeat
      Posn := Posn+1;
      if Posn <= Length(formula) then
        CurrChar := formula[Posn]
      else
        CurrChar := ^M;
   until CurrChar<>' ';
  end {ParseNext};

  function add_subt: Real;
  var
    E: Real;
    Opr: Char;

    function mult_DIV: Real;
    var
      S   : Real;
      Opr : Char;

      function Power: Real;
      var
        T : Real;

        function Signedop: Real;

          function Unsignedop: Real;
          type
            StdFunc = (fabs,    fsqrt, fsqr, fsin, fcos,
                       farctan, fln,   flog, fexp, ffact);
            StdFuncList = array[StdFunc] of String[6];

          const
            StdFuncName: StdFuncList =
            ('ABS','SQRT','SQR','SIN','COS',
            'ARCTAN','LN','LOG','EXP','FACT');
          var
            E, L, Start    : Integer;
            Funnet         : Boolean;
            F              : Real;
            Sf             : StdFunc;

            function Fact(I: Integer): Real;
            begin
              if I > 0 then
              begin
                Fact := I*Fact(I-1);
              end
              else
                Fact := 1;
            end {Fact};

          begin {function Unsignedop}
            if CurrChar in Digit then
            begin
              Start := Posn;
              repeat
                ParseNext
              until not (CurrChar in Digit);
              if CurrChar = '.' then
                repeat
                  ParseNext
                until not (CurrChar in Digit);
              if CurrChar = 'E' then
              begin
                ParseNext;
                repeat
                  ParseNext
                until not (CurrChar in Digit);
              end;
              Val(Copy(formula,Start,Posn-Start),F,ErrPos);
            end
            else if CurrChar = '(' then
            begin
              ParseNext;
              F := add_subt;
              if CurrChar=')' then
                ParseNext
              else
                ErrPos := Posn;
            end
            else
            begin
              Funnet := False;
              for sf := fabs tO ffact do
                if not Funnet then
                begin
                  l := Length(StdFuncName[sf]);
                  if Copy(formula,Posn,l)=StdFuncName[sf] then
                  begin
                    Posn := Posn+l-1;
                    ParseNext;
                    f := Unsignedop;
                    case sf of
                      fabs:     f := abs(f);
                      fsqrt:    f := SqrT(f);
                      fsqr:     f := Sqr(f);
                      fsin:     f := Sin(f);
                      fcos:     f := Cos(f);
                      farctan:  f := ArcTan(f);
                      fln :     f := LN(f);
                      flog:     f := LN(f)/LN(10);
                      fexp:     f := EXP(f);
                      ffact:    f := fact(Trunc(f));
                    end;
                    Funnet := True;
                  end;
                end;
              if not Funnet then
              begin
                ErrPos := Posn;
                f := 0;
              end;
            end;
            Unsignedop := F;
          end {Unsignedop};

        begin {Signedop}
          if CurrChar='-' then
          begin
            ParseNext;
            Signedop := -Unsignedop;
          end
          else
            Signedop := Unsignedop;
        end {Signedop};

      begin {Power}
        T := Signedop;
        while CurrChar='^' do
        begin
          ParseNext;
          if t <> 0 then
            t := EXP(LN(abs(t))*Signedop)
          else
            t := 0;
        end;
        Power := t;
      end {Power};

    begin {mult_DIV}
      s := Power;
      while CurrChar in ['*','/'] do
      begin
        Opr := CurrChar;
        ParseNext;
        case Opr of
          '*': s := s * Power;
          '/': s := s / Power;
        end;
      end;
      mult_DIV := s;
    end {mult_DIV};

  begin {add_subt}
    E := mult_DIV;
    while CurrChar in ['+','-'] do
    begin
      Opr := CurrChar;
      ParseNext;
      case Opr of
        '+': e := e + mult_DIV;
        '-': e := e - mult_DIV;
      end;
    end;
    add_subt := E;
  end {add_subt};

begin {PROC Eval}
  if formula[1] = '.' then
    formula := '0' + formula;
  if formula[1]='+' then
    Delete(formula,1,1);
  for Posn:=1 to Length(formula) do
    formula[Posn] := Upcase(formula[Posn]);
  Posn := 0;
  ParseNext;
  Value := add_subt;
  if CurrChar=^M then
    ErrPos := 0
  else
    ErrPos := Posn;
end {PROC Eval};

procedure Tform1.Button1Click(Sender: TObject);
var
  Value: double;
  ErrPos: Integer;
begin
  Eval(Edit1.Text, Value, ErrPos);
  Label1.Caption := FloatToStr(Value); // 결과값

  if ErrPos > 0 then // 에러가 있다면 해당 문자로 캐럿을 위치 시킨다
  begin
    Edit1.SetFocus;
    {두번째 문자 위치로 커서를 보낸대}
    Edit1.SelStart := ErrPos - 1;
    {문자를 선택하지 않은 상태로 만든다}
    Edit1.SelLength := 0;
  end;
end;

end.





411   [윈도우즈 API] 모서리가 둥근(rounded ends) TEdit 만들기  김영대 2003/03/07 4895 1286
410   [일반/컴포넌트] TOpenDialog 의 '선택','취소' 버튼 이름 바꾸기  김영대 2003/03/07 4360 1333
409   [윈도우즈 API] 레지스트리 전체 검색하기  김영대 2003/03/07 4199 1137
408   [윈도우즈 API] ALT_F4 hot key 가로채기  김영대 2003/03/07 5635 1614
407   [데이터베이스] 동적으로 SELECT의 GROUP BY 문 만들기  김영대 2003/03/07 4185 945
406   [일반/컴포넌트] ListView 의 item 을 강제로 편집상태로 만들기  김영대 2003/03/07 4645 1215
405   [일반/컴포넌트] MessageDlg()의 폰트를 바꾸어서 띄우기  김영대 2003/03/07 3865 1066
404   [윈도우즈 API] 윈도우즈 탐색기의 파일, 컴퓨터 찾기 화면 띄우기  김영대 2003/03/07 6166 1628
403   [일반/컴포넌트] WideString 을 String 으로 바꾸기  김영대 2003/03/07 4494 1118
402   [윈도우즈 API] 다른 Application의 화면에 글자,그림을 출력하기  김영대 2003/03/07 3381 868
401   [윈도우즈 API] 윈도우즈 '시작' 메뉴 Refresh 시키기  김영대 2003/03/07 4609 1419
400   [일반/컴포넌트] StringGrid 에서 프로그램으로 MultiSelect 시키기  김영대 2003/03/06 5411 1187
399   [일반/컴포넌트] StringGrid 의 선택영역만 클립보드로 복사하기  김영대 2003/03/06 4863 1077
398   [윈도우즈 API] RichEdit에 입력한 문장의 실제 높이 구하기  김영대 2003/03/06 5046 1429
397   [윈도우즈 API] DDE 쓰지 않고 IE의 현재 URL 가져오기  김영대 2003/03/06 5986 1676
396   [일반/컴포넌트] Memo의 행의 문자수를 제한하고 WordWrap시키기  김영대 2003/03/06 5231 1314
395   [일반/컴포넌트] OEM conversion  김영대 2003/03/06 4322 1265
394   [일반/컴포넌트] ASCII printing  김영대 2003/03/06 5282 1213
393   [COM/OLE] Delphi의 OCX를 InstallShield로 배포하는 방법  김영대 2003/03/06 8333 5623
392   [데이터베이스] Save DBGrid To Excel  김영대 2003/03/06 6993 1849
391   [일반/컴포넌트] StringGrid 의 내용을 클립보드로 복사하기  김영대 2003/03/06 4467 1060
390   [윈도우즈 API] 레지스트리의 변경여부 알리는 2가지 방법  김영대 2003/03/06 4760 1282
389   [일반/컴포넌트] desktop 배경화면을 폼의 배경화면으로 그리기  김영대 2003/03/06 3677 1037
388   [멀티미디어] JPEG, WAVE 를 resource 파일에 넣고 읽어오기  김영대 2003/03/06 5262 1224
387   [시스템] 마이크 볼륨 조절하기  김영대 2003/03/06 4651 1285
386   [일반/컴포넌트] 윈도우즈 "날짜/시간" 설정화면 띄우기  김영대 2003/03/06 6207 1822
385   [시스템] 오디오 CD의 볼륨 조절하기  김영대 2003/03/06 3616 1026
  [일반/컴포넌트] 문자열 수식문장(expression)의 결과 구하기  김영대 2003/03/06 3378 878
383   [일반/컴포넌트] 특정 Color의 Invert Color 구하기  김영대 2003/03/06 4313 1315
382   [일반/컴포넌트] 두개의 RichEdit 사이에 내용 복사하기  김영대 2003/03/06 5859 1364
381   [시스템] Redirecting DOS Application Output  김영대 2003/03/06 4642 1207
380   [시스템] How do I use SetWindowsHookEx ?  김영대 2003/03/06 6839 957
379   [윈도우즈 API] KeyDown의 Beep음을 없애자...  김영대 2003/03/06 4632 1211
378   [데이터베이스] 특정 폼의 현재 편집중인 DB Field 구하기  김영대 2003/03/06 4089 1111
377   [윈도우즈 API] 프로그램으로 Screensaver 등록하는 두가지 방법  김영대 2003/03/06 4501 1268
376   [일반/컴포넌트] TObject의 프로퍼티를 문자열로 참조하기  김영대 2003/03/06 5227 1594
375   [윈도우즈 API] 외부 프로그램을 최상위로 설정하기  김영대 2003/03/06 5226 1234
374   [일반/컴포넌트] 이미지를 마우스로 drag 해서 zoom 하기  김영대 2003/03/06 3606 1023
373   [윈도우즈 API] 폴더나 파일의 윈도우즈 등록정보 dialog 띄우기  김영대 2003/03/06 5098 1475
372   [네트웍/인터넷] How to bring a network down - "Win Nuke"  김영대 2003/03/06 7310 1994

[이전 10개] [1]..[11][12][13][14] 15 [16][17][18][19][20]..[25] [다음 10개]
 

Copyright 1999-2022 Zeroboard / skin by zero