::: 델파이 Tip&Trick :::

델파이 Tip&Trick 성격에 맞지 않는 광고,비방,질문의 글은 즉시 삭제하며
내용을 복사하여 사용할 경우 반드시 이곳(http://www.howto.pe.kr)을 출처로 명시하여 주세요


Category

  김영대(2003-03-06 21:36:41, Hit : 5927, Vote : 1379) 
 두개의 RichEdit 사이에 내용 복사하기

// 아래의 소스을 clCopyRTF.pas 파일로 만들어서 unit으로 사용하세요

unit clCopyRTF;

{written by Mike Orriss (mjo@3kcc.co.uk)

This unit provides a simple method of copying RTF text
between two RichEdit controls (see CopyRTF procedure below).

Data copied will be the source selected text or the whole
source if there is none selected.

The copied data will replace the destination selected text
or be inserted at the current caret position
}

interface

uses Windows,Classes,ComCtrls,richedit;

procedure CopyRTF(source,dest: TRichEdit);

implementation

{$IFNDEF VER120}
type TEditStreamCallBack = function (dwCookie: Longint; pbBuff: PByte;
                                     cb: Longint; var pcb: Longint): Longint; stdcall;

  TEditStream = record
    dwCookie: Longint;
    dwError: Longint;
    pfnCallback: TEditStreamCallBack;
  end;
{$ENDIF}

//---------------------------------------------------------------------------//
function InCallback(dwCookie: Longint; pbBuff: PByte; cb: Longint; var pcb: Longint): Longint; stdcall;
var stream: TStream;
var bytes: LongInt;
begin
  stream := TStream(dwCookie);
  bytes := stream.Size-stream.Position;
  if bytes > cb then bytes := cb;
  pcb := stream.Read(pbBuff^,bytes);
  Result := 0;
end;

//---------------------------------------------------------------------------//
function OutCallback(dwCookie: Longint; pbBuff: PByte; cb: Longint; var pcb: Longint): Longint; stdcall;
begin
  if cb > 0 then pcb := TStream(dwCookie).Write(pbBuff^,cb);
  Result := 0;
end;

//---------------------------------------------------------------------------//
procedure GetRTF(re: TRichEdit; stream: TStream);
var editstream: TEditStream;
begin
  editstream.dwCookie:= Longint(stream);
  editstream.dwError:= 0;
  editstream.pfnCallback:= OutCallBack;
  re.Perform(EM_STREAMOUT,SF_RTF or SFF_SELECTION,longint(@editstream));
  stream.Position := 0;
end;

//---------------------------------------------------------------------------//
procedure PutRTF(re: TRichEdit; stream: TStream);
var editstream: TEditStream;
begin
  editstream.dwCookie:= Longint(stream);
  editstream.dwError:= 0;
  editstream.pfnCallback:= InCallBack;
  re.Perform(EM_STREAMIN,SF_RTF or SFF_SELECTION,longint(@editstream));
end;

//---------------------------------------------------------------------------//
procedure CopyRTF(source,dest: TRichEdit);
var mstream: TMemoryStream;
begin
  if source.GetTextLen=0 then exit;

  mstream := TMemoryStream.Create;
  try
    if source.SelLength=0 then begin
      source.SelStart := 0;
      source.SelLength := source.GetTextLen;
    end;
    GetRTF(source,mstream);
    PutRTF(dest,mstream);
  finally
    mstream.Free;
  end;
end;

end.



411   [윈도우즈 API] 모서리가 둥근(rounded ends) TEdit 만들기  김영대 2003/03/07 4989 1289
410   [일반/컴포넌트] TOpenDialog 의 '선택','취소' 버튼 이름 바꾸기  김영대 2003/03/07 4383 1336
409   [윈도우즈 API] 레지스트리 전체 검색하기  김영대 2003/03/07 4229 1144
408   [윈도우즈 API] ALT_F4 hot key 가로채기  김영대 2003/03/07 5665 1621
407   [데이터베이스] 동적으로 SELECT의 GROUP BY 문 만들기  김영대 2003/03/07 4208 947
406   [일반/컴포넌트] ListView 의 item 을 강제로 편집상태로 만들기  김영대 2003/03/07 4677 1227
405   [일반/컴포넌트] MessageDlg()의 폰트를 바꾸어서 띄우기  김영대 2003/03/07 3920 1072
404   [윈도우즈 API] 윈도우즈 탐색기의 파일, 컴퓨터 찾기 화면 띄우기  김영대 2003/03/07 6196 1632
403   [일반/컴포넌트] WideString 을 String 으로 바꾸기  김영대 2003/03/07 4531 1131
402   [윈도우즈 API] 다른 Application의 화면에 글자,그림을 출력하기  김영대 2003/03/07 3409 870
401   [윈도우즈 API] 윈도우즈 '시작' 메뉴 Refresh 시키기  김영대 2003/03/07 4632 1420
400   [일반/컴포넌트] StringGrid 에서 프로그램으로 MultiSelect 시키기  김영대 2003/03/06 5497 1195
399   [일반/컴포넌트] StringGrid 의 선택영역만 클립보드로 복사하기  김영대 2003/03/06 4922 1093
398   [윈도우즈 API] RichEdit에 입력한 문장의 실제 높이 구하기  김영대 2003/03/06 5082 1432
397   [윈도우즈 API] DDE 쓰지 않고 IE의 현재 URL 가져오기  김영대 2003/03/06 6013 1684
396   [일반/컴포넌트] Memo의 행의 문자수를 제한하고 WordWrap시키기  김영대 2003/03/06 5273 1317
395   [일반/컴포넌트] OEM conversion  김영대 2003/03/06 4355 1267
394   [일반/컴포넌트] ASCII printing  김영대 2003/03/06 5354 1226
393   [COM/OLE] Delphi의 OCX를 InstallShield로 배포하는 방법  김영대 2003/03/06 8412 5649
392   [데이터베이스] Save DBGrid To Excel  김영대 2003/03/06 7147 1967
391   [일반/컴포넌트] StringGrid 의 내용을 클립보드로 복사하기  김영대 2003/03/06 4509 1063
390   [윈도우즈 API] 레지스트리의 변경여부 알리는 2가지 방법  김영대 2003/03/06 4803 1289
389   [일반/컴포넌트] desktop 배경화면을 폼의 배경화면으로 그리기  김영대 2003/03/06 3731 1040
388   [멀티미디어] JPEG, WAVE 를 resource 파일에 넣고 읽어오기  김영대 2003/03/06 5377 1231
387   [시스템] 마이크 볼륨 조절하기  김영대 2003/03/06 4692 1291
386   [일반/컴포넌트] 윈도우즈 "날짜/시간" 설정화면 띄우기  김영대 2003/03/06 6230 1828
385   [시스템] 오디오 CD의 볼륨 조절하기  김영대 2003/03/06 3670 1029
384   [일반/컴포넌트] 문자열 수식문장(expression)의 결과 구하기  김영대 2003/03/06 3446 896
383   [일반/컴포넌트] 특정 Color의 Invert Color 구하기  김영대 2003/03/06 4339 1323
  [일반/컴포넌트] 두개의 RichEdit 사이에 내용 복사하기  김영대 2003/03/06 5927 1379
381   [시스템] Redirecting DOS Application Output  김영대 2003/03/06 4743 1226
380   [시스템] How do I use SetWindowsHookEx ?  김영대 2003/03/06 6961 964
379   [윈도우즈 API] KeyDown의 Beep음을 없애자...  김영대 2003/03/06 4694 1218
378   [데이터베이스] 특정 폼의 현재 편집중인 DB Field 구하기  김영대 2003/03/06 4113 1118
377   [윈도우즈 API] 프로그램으로 Screensaver 등록하는 두가지 방법  김영대 2003/03/06 4538 1275
376   [일반/컴포넌트] TObject의 프로퍼티를 문자열로 참조하기  김영대 2003/03/06 5249 1600
375   [윈도우즈 API] 외부 프로그램을 최상위로 설정하기  김영대 2003/03/06 5279 1240
374   [일반/컴포넌트] 이미지를 마우스로 drag 해서 zoom 하기  김영대 2003/03/06 3644 1030
373   [윈도우즈 API] 폴더나 파일의 윈도우즈 등록정보 dialog 띄우기  김영대 2003/03/06 5124 1483
372   [네트웍/인터넷] How to bring a network down - "Win Nuke"  김영대 2003/03/06 7353 2002

[이전 10개] [1]..[11][12][13][14] 15 [16][17][18][19][20]..[25] [다음 10개]
 

Copyright 1999-2023 Zeroboard / skin by zero