::: 델파이 Tip&Trick :::

델파이 Tip&Trick 성격에 맞지 않는 광고,비방,질문의 글은 즉시 삭제하며
내용을 복사하여 사용할 경우 반드시 이곳(http://www.howto.pe.kr)을 출처로 명시하여 주세요


Category

  김영대(2003-03-07 20:22:18, Hit : 4916, Vote : 1264
 네트워크 컴퓨터가 존재하는지 검사하기

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  StdCtrls;

type
  TForm1 = class(TForm)
    Edit1: TEdit;
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation
{$R *.DFM}

function RemoteComputerExists(const ComputerName : String) : Boolean;
{
  Returns True if the remote computer ComputerName exists on the network.
  ComputerName must be of the form "\Name".  The function is not case-sensitive.
  Be warned that this may take a *long* time to return.

  Based on code supplied by:
  Michael P. Bobowski
  Atled Engineering Group
  Milwaukee, WI
  <mbobo@execpc.com>
}
  function Enumerate(lpnr : PNetResource; const ComputerName : String): Boolean;
  type
    TNetResourceArray = array[0..16383] of TNetResource;
    PNetResourceArray = ^TNetResourceArray;
  var
    hEnum: THandle;
    BufferSize, NumEntries, Entry: Integer;
    lpnrLocalc: PNetResourceArray;
  begin
    Result := False;
    if NO_ERROR <> WNetOpenEnum(RESOURCE_GLOBALNET, RESOURCETYPE_ANY, 0 {Usage: All resources}, lpnr, hEnum) then
    begin
      Exit;
    end;
    BufferSize := 16384; {16 kB}
    {Get as many entries as possible; NumEntries will be set to the number actually read (if successfull)}
    NumEntries := $FFFFFFFF;
    lpnrLocalc := AllocMem(BufferSize);
    repeat
      case WNetEnumResource(hEnum, NumEntries, lpnrLocalc, BufferSize) of
      NO_ERROR : begin
        for Entry := 0 to (NumEntries - 1) do
        begin
          {lpnrLocalc^[Entry].dwScope will be RESOURCE_GLOBALNET since that is what we asked for}
          if 0 = ANSICompareText(lpnrLocalc^[Entry].lpRemoteName,ComputerName) then
          begin
            {lpnrLocalc^[Entry].dwDisplayType = RESOURCEDISPLAYTYPE_SERVER should also be True}
            {RESOURCEUSAGE_CONTAINER = (lpnrLocalc^[Entry].dwUsage and RESOURCEUSAGE_CONTAINER) should also be True}
            Result := True;
            break;
          end; {then}
          {ResourceType is irrelevant}

          if (lpnrLocalc^[Entry].dwDisplayType = RESOURCEDISPLAYTYPE_DOMAIN) or
             (lpnrLocalc^[Entry].dwDisplayType = RESOURCEDISPLAYTYPE_NETWORK) then
          begin
            {Must recurse}
            if RESOURCEUSAGE_CONTAINER = (lpnrLocalc^[Entry].dwUsage and RESOURCEUSAGE_CONTAINER) then
            begin
              {Recursion possible}
              Result := Enumerate(@(lpnrLocalc^[Entry]), ComputerName);
              if Result then
                break;
            end; {then}
          end; {then}
        end; {for}
      end; {NO_ERROR}

      ERROR_MORE_DATA : begin
        {The buffer is too small for even one entry: increase the buffer...}
        FreeMem(lpnrLocalc, BufferSize);
        BufferSize := 2*BufferSize;
        lpnrLocalc := AllocMem(BufferSize);
        {...and try again}
        end; {ERROR_MORE_DATA}
      else
      {
      ERROR_NO_MORE_ITEMS  (Enumeration is complete)
      ERROR_INVALID_HANDLE (The handle given by the hEnum parameter is not valid)
      ERROR_NO_NETWORK     (No network is present)
      ERROR_EXTENDED_ERROR (use WNetGetLastError for details)
      }
         break;
      end; {case}
    until Result;

    FreeMem(lpnrLocalc, BufferSize);
    WNetCloseEnum(hEnum);
  end; {Enumerate}

begin
  {Start enumeration at the root of the network}
  Result := Enumerate(Nil, ComputerName);
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  // Edit.Text에 컴퓨터 이름을 사용자가 입력함
  if Pos('\', Edit1.Text) = 0 then
    Edit1.Text := '\'+Edit1.Text;

  if RemoteComputerExists(Edit1.Text) then
    ShowMessage('네트워크 컴퓨터가 존재합니다 ')
  else
    ShowMessage('네트워크 컴퓨터가 존재하지 않습니다 ');
end;

end.





451   [일반/컴포넌트] 파일의 변경/생성/사용한 날짜 바꾸기  김영대 2003/03/07 4976 1262
450   [시스템] 설치된 modem 리스트 구하기  김영대 2003/03/07 4903 1418
449   [윈도우즈 API] Windows 3.1x/32s/95/98/NT 구분하기  김영대 2003/03/07 2975 888
448   [시스템] WM_COPYDATA 메시지를 사용한 IPC  김영대 2003/03/07 6630 1638
447   [시스템] 마우스의 좌,우 버튼의 동작 바꾸기  김영대 2003/03/07 4208 1193
446   [윈도우즈 API] window의 maximize, minimize 알아내기  김영대 2003/03/07 4611 1205
445   [시스템] WM_COPYDATA 메시지를 사용한 IPC 2  김영대 2003/03/07 5691 1595
444   [윈도우즈 API] 데스크탑 아이콘 전부 감추기/보이기  김영대 2003/03/07 3938 1162
443   [윈도우즈 API] 바탕화면, 시작메뉴 icon 숨기기  김영대 2003/03/07 5150 1257
442   [시스템] 마우스가 설치되어 있는지 검사하기  김영대 2003/03/07 6776 1835
441   [일반/컴포넌트] Memo의 입력 행수/열수 제한하기  김영대 2003/03/07 3786 1248
440   [일반/컴포넌트] 윈도우즈 파일명의 무효한 구성문자  김영대 2003/03/07 4686 1481
439   [시스템] 파일이 다른 프로그램에 의해 사용중인지 검사  김영대 2003/03/07 6203 1459
438   [시스템] 일정시간 경과후 없어지는 MessageBox  김영대 2003/03/07 6953 1382
437   [시스템] CPU speed 구하기 2  김영대 2003/03/07 4143 1183
436   [네트웍/인터넷] LAN 에 접속했는지 검사하기  김영대 2003/03/07 4478 1210
435   [일반/컴포넌트] TIFF Images and manipulation  김영대 2003/03/07 4912 1186
434   [시스템] reboot 95/98/NT  김영대 2003/03/07 4515 1290
433   [네트웍/인터넷] Ethernet 랜카드의 MAC adress 구하기  김영대 2003/03/07 7303 1907
432   [네트웍/인터넷] Serial Port 사용하기  김영대 2003/03/07 6740 1763
431   [윈도우즈 API] IE의 현재 url 가져오기  김영대 2003/03/07 4595 1154
430   [시스템] DOS-matrix 프린터에 인쇄하기  김영대 2003/03/07 4531 1220
429   [윈도우즈 API] 윈도우즈 "시작" 메뉴를 내 프로그램 안으로...  김영대 2003/03/07 4577 1247
428   [윈도우즈 API] 모든 창을 아이콘 표시/취소  김영대 2003/03/07 4218 1228
427   [일반/컴포넌트] RichEdit 화면에 보여지는 첫번째/마지막 행번호  김영대 2003/03/07 5450 1443
  [네트웍/인터넷] 네트워크 컴퓨터가 존재하는지 검사하기  김영대 2003/03/07 4916 1264
425   [일반/컴포넌트] 텍스트 파일 합치기(Merging)  김영대 2003/03/07 5082 1139
424   [일반/컴포넌트] TRichEdit를 사용한 syntax highlighting 예제  김영대 2003/03/07 6533 1743
423   [네트웍/인터넷] NetMask 알아내기  김영대 2003/03/07 7202 1849
422   [윈도우즈 API] Application의 최소화시 Zooming 효과 주기2  김영대 2003/03/07 5509 1455
421   [시스템] drive의 일련번호 바꾸기  김영대 2003/03/07 6531 1537
420   [시스템] CPU의 사용률 구하기  김영대 2003/03/07 4971 1278
419   [일반/컴포넌트] 숫자의 근사치 구하기  김영대 2003/03/07 4188 1121
418   [윈도우즈 API] How to flush key buffer  김영대 2003/03/07 4435 1179
417   [COM/OLE] 윈도우즈 시작의 "실행" 화면 띄우기  김영대 2003/03/07 4008 1128
416   [윈도우즈 API] 작업관리자의 task switching 금지시키기  김영대 2003/03/07 4646 1221
415   [네트웍/인터넷] 인터넷에 LAN 또는 Modem으로 접속중인지 검사  김영대 2003/03/07 4935 1302
414   [윈도우즈 API] Window Handle 로 실행파일명 구하기  김영대 2003/03/07 4709 1215
413   [네트웍/인터넷] Getting Novell Netware Login NAME  김영대 2003/03/07 3501 981
412   [일반/컴포넌트] ListBox의 화면에 보여지는 최상위 Item 번호  김영대 2003/03/07 4307 1174

[이전 10개] [1]..[11][12][13] 14 [15][16][17][18][19][20]..[25] [다음 10개]
 

Copyright 1999-2022 Zeroboard / skin by zero