::: 델파이 Tip&Trick :::

델파이 Tip&Trick 성격에 맞지 않는 광고,비방,질문의 글은 즉시 삭제하며
내용을 복사하여 사용할 경우 반드시 이곳(http://www.howto.pe.kr)을 출처로 명시하여 주세요


Category

  김영대(2003-03-07 22:16:49, Hit : 5562, Vote : 1247
 모든 TCP/IP interfaces 의 IP/Netmask 구하기

This is a complete Delphi unit. By adding it to a project you can
call :

   EnumInterfaces(var s string): Boolean;

that returns a CRLF separated string of all IP addresses, netmasks,
broadcast addresses and interface status.

--------------------------------------------------------------------

unit USock;

interface

uses Windows, Winsock;

{

  This function enumerates all TCP/IP interfaces and
  returns a CRLF separated string containing:

  IP, NetMask, BroadCast-Address, Up/Down status,
  Broadcast support, Loopback

  If you feed this string to a wide TMEMO (to its memo.lines.text
  property) you will see cleary the results.

  To use this you need Win98/ME/2K, 95 OSR 2 or NT service
  pack #3 because WinSock 2 is used (WS2_32.DLL)

}

function EnumInterfaces(var sInt: string): Boolean;

{ Imported function WSAIOCtl from Winsock 2.0 - Winsock 2 is }
{ available only in Win98/ME/2K and 95 OSR2, NT srv pack #3 }

function WSAIoctl(s: TSocket; cmd: DWORD; lpInBuffer: PCHAR; dwInBufferLen:
  DWORD;
  lpOutBuffer: PCHAR; dwOutBufferLen: DWORD;
  lpdwOutBytesReturned: LPDWORD;
  lpOverLapped: POINTER;
  lpOverLappedRoutine: POINTER): Integer; stdcall; external 'WS2_32.DLL';

{ Constants taken from C header files }

const SIO_GET_INTERFACE_LIST = $4004747F;
  IFF_UP = $00000001;
  IFF_BROADCAST = $00000002;
  IFF_LOOPBACK = $00000004;
  IFF_POINTTOPOINT = $00000008;
  IFF_MULTICAST = $00000010;

type sockaddr_gen = packed record
    AddressIn: sockaddr_in;
    filler: packed array[0..7] of char;
  end;

type INTERFACE_INFO = packed record
    iiFlags: u_long; // Interface flags
    iiAddress: sockaddr_gen; // Interface address
    iiBroadcastAddress: sockaddr_gen; // Broadcast address
    iiNetmask: sockaddr_gen; // Network mask
  end;

implementation

{-------------------------------------------------------------------

1. Open WINSOCK
2. Create a socket
3. Call WSAIOCtl to obtain network interfaces
4. For every interface, get IP, MASK, BROADCAST, status
5. Fill a CRLF separated string with this info
6. Finito

--------------------------------------------------------------------}

function EnumInterfaces(var sInt: string): Boolean;
var s: TSocket;
  wsaD: WSADATA;
  NumInterfaces: Integer;
  BytesReturned, SetFlags: u_long;
  pAddrInet: SOCKADDR_IN;
  pAddrString: PCHAR;
  PtrA: pointer;
  Buffer: array[0..20] of INTERFACE_INFO;
  i: Integer;
begin
  result := true;                               // Initialize
  sInt := '';

  WSAStartup($0101, wsaD);                      // Start WinSock
                                                // You should normally check
                                                // for errors here :)

  s := Socket(AF_INET, SOCK_STREAM, 0);         // Open a socket
  if (s = INVALID_SOCKET) then exit;

  try                                           // Call WSAIoCtl
    PtrA := @bytesReturned;
    if (WSAIoCtl(s, SIO_GET_INTERFACE_LIST, nil, 0, @Buffer, 1024, PtrA, nil,
      nil)
      <> SOCKET_ERROR)
      then
    begin                                       // If ok, find out how
                                                // many interfaces exist

      NumInterfaces := BytesReturned div SizeOf(INTERFACE_INFO);

      for i := 0 to NumInterfaces - 1 do        // For every interface
      begin
        pAddrInet := Buffer[i].iiAddress.addressIn;           // IP ADDRESS
        pAddrString := inet_ntoa(pAddrInet.sin_addr);
        sInt := sInt + ' IP=' + pAddrString + ',';
        pAddrInet := Buffer[i].iiNetMask.addressIn;           // SUBNET MASK
        pAddrString := inet_ntoa(pAddrInet.sin_addr);
        sInt := sInt + ' Mask=' + pAddrString + ',';
        pAddrInet := Buffer[i].iiBroadCastAddress.addressIn;  // Broadcast addr
        pAddrString := inet_ntoa(pAddrInet.sin_addr);
        sInt := sInt + ' Broadcast=' +  pAddrString + ',';

        SetFlags := Buffer[i].iiFlags;
        if (SetFlags and IFF_UP) = IFF_UP then
          sInt := sInt + ' Interface UP,'                   // Interface up/down
        else
          sInt := sInt + ' Interface DOWN,';

        if (SetFlags and IFF_BROADCAST) = IFF_BROADCAST then  // Broadcasts
          sInt := sInt + ' Broadcasts supported,'              // supported or
        else                                                  // not supported
          sInt := sInt + ' Broadcasts NOT supported,';

        if (SetFlags and IFF_LOOPBACK) = IFF_LOOPBACK then    // Loopback or
          sInt := sInt + ' Loopback interface'
        else
          sInt := sInt + ' Network interface';                 // normal

        sInt := sInt + #13#10;                                // CRLF between
                                                              // each interface
      end;
    end;
  except
  end;
//
// Close sockets
//
  CloseSocket(s);
  WSACleanUp;
  result := false;
end;

end.





491   [네트웍/인터넷] 네트워크 컴퓨터가 존재하는지 검사하기  김영대 2003/03/07 4892 1261
490   [일반/컴포넌트] OEM conversion  김영대 2003/03/06 4258 1261
489   [윈도우즈 API] Bitmap을 Icon으로 바꾸려면...  김영대 2003/03/05 4453 1261
488   [일반/컴포넌트] PageControl 에서 미리 이동하려는 Sheet 알아내어 제어하기  김영대 2004/09/13 4938 1260
487   [윈도우즈 API] "시작"->"프로그램" 메뉴에 폴더 추가하기  김영대 2003/03/29 4877 1260
486   [시스템] Windows 9x/ME/NT/2000/XP 버전 구별  김영대 2003/03/07 4653 1260
485   [일반/컴포넌트] 파일의 변경/생성/사용한 날짜 바꾸기  김영대 2003/03/07 4959 1260
484   [시스템] IP Address 윈도우 폼위에 만들어보기  구창민 2003/03/14 5401 1259
483   [일반/컴포넌트] StrToFloatDef  김영대 2003/11/13 4927 1258
482   [일반/컴포넌트] Zlib 를 이용한 압축과 해제  김영대 2004/08/03 5413 1257
481   [윈도우즈 API] 바탕화면, 시작메뉴 icon 숨기기  김영대 2003/03/07 5143 1257
480   [윈도우즈 API] Windows Logon 사용자명, 컴퓨터명  김영대 2003/03/05 4658 1257
479   [윈도우즈 API] 화면의 Memo 가 보여줄 수 있는 라인수 알아내기  김영대 2003/03/05 4965 1257
478   [시스템] 파일 복사하면서 진행상태와 남은 시간 표시하기  김영대 2003/04/10 6067 1255
477   [일반/컴포넌트] JPEG, Bitmap 상호 변환하여 파일로 저장하기  김영대 2003/03/07 4336 1255
476   [윈도우즈 API] 프로그램으로 Screensaver 등록하는 두가지 방법  김영대 2003/03/06 4403 1255
475   [윈도우즈 API] "임시 인터넷 파일" 전부 지우기  김영대 2003/03/26 5222 1254
474   [윈도우즈 API] 파일에서 아이콘 빼내기(16 * 16)  김영대 2003/03/07 4684 1254
473   [시스템] 윈도우즈 네트워크에 접속했는지 검사  김영대 2003/03/04 4659 1253
472   [일반/컴포넌트] 메뉴 아이템의 동적 추가와 그림넣기  김영대 2003/03/04 7842 1253
471   [일반/컴포넌트] StringGrid에서 Enter Key를 Tab Key와 같은 효과  김영대 2003/03/04 5447 1253
470   [일반/컴포넌트] TStringGrid 의 모든 행에 행선택 CheckBox 두기  김영대 2004/09/06 5606 1252
469   [시스템] ROM-BIOS 정보 읽기  김영대 2003/03/07 5292 1252
468   [일반/컴포넌트] Delphi의 Tokenizer TParser 사용 예제  김영대 2003/03/31 4784 1251
467   [데이터베이스] DB에 저장된 JPEG(JPG)를 DBGrid에 출력하기  김영대 2003/03/06 5186 1251
466   [윈도우즈 API] 폼이 최대화될때 특정루틴 실행하기  김영대 2003/03/05 4401 1251
465   [윈도우즈 API] '알려진 파일 형식의 파일 확장명 숨김' 여부  김영대 2004/08/25 4954 1250
464   [시스템] 마우스 포인터 속도 바꾸기  김영대 2003/03/06 4933 1250
463   [시스템] 외부 프로그램 종료 시키기  김영대 2004/08/02 6410 1249
462   [일반/컴포넌트] 문자열 찾아서(Search) 바꾸기(Replace)  김영대 2003/03/04 4163 1249
461   [일반/컴포넌트] VB Left$(), Right$(), LTrim$() ...  김영대 2003/03/04 4983 1249
460   [일반/컴포넌트] 전각문자인지 반각문자인지 검사하기  김영대 2003/03/07 6643 1248
459   [일반/컴포넌트] Memo의 입력 행수/열수 제한하기  김영대 2003/03/07 3774 1248
  [네트웍/인터넷] 모든 TCP/IP interfaces 의 IP/Netmask 구하기  김영대 2003/03/07 5562 1247
457   [일반/컴포넌트] 투명한(Transparent) TPanel 콤포넌트  김영대 2003/03/07 5129 1247
456   [윈도우즈 API] 윈도우즈 "시작" 메뉴를 내 프로그램 안으로...  김영대 2003/03/07 4562 1247
455   [일반/컴포넌트] RichEdit에서 HTML 태그를 다른색으로 표시하기  김영대 2003/03/07 5551 1246
454   [윈도우즈 API] Control의 repainting 금지하여 깜박임 줄이기  김영대 2003/03/07 5446 1246
453   [윈도우즈 API] 시스템 메뉴에서 menu item 제거하기  김영대 2003/03/05 4622 1246
452   [윈도우즈 API] 윈도우즈 전화걸기 화면 띄우기  김영대 2003/03/07 4617 1245

[이전 10개] [1]..[11][12] 13 [14][15][16][17][18][19][20]..[25] [다음 10개]
 

Copyright 1999-2021 Zeroboard / skin by zero