Uses richedit;
procedure TForm1.Button1Click(Sender: TObject);
var
r: TRect;
richedit_outputarea: TRect;
printresX, printresY: Integer;
fmtRange: TFormatRange;
begin
printer.begindoc;
try
with Printer.Canvas do
begin
printresX := GetDeviceCaps( handle, LOGPIXELSX);
printresY := GetDeviceCaps( handle, LOGPIXELSY);
r:= Rect(
printresX, // 1 inch left margin
printresY * 3 div 2, // 1.5 inch top margin
Printer.PageWidth - printresX, // 1 inch right margin
Printer.PageHeight - printresY * 3 div 2 // 1.5 inch bottom margin
);
// Define a rectangle for the rich edit text. The height is set to the
// maximum. But we need to convert from device units to twips,
// 1 twip = 1/1440 inch or 1/20 point.
richedit_outputarea :=
Rect( r.left * 1440 div printresX,
r.top * 1440 div printresY,
r.right * 1440 div printresX,
r.bottom* 1440 div printresY );
// Tell rich edit to format its text to the printer. First set
// up data record for message:
fmtRange.hDC := Handle; // printer handle
fmtRange.hdcTarget := Handle; // ditto
fmtRange.rc := richedit_outputarea;
fmtRange.rcPage :=
Rect( 0, 0,
Printer.PageWidth * 1440 div printresX,
Printer.PageHeight * 1440 div printresY );
fmtRange.chrg.cpMin := richedit1.SelStart;
fmtRange.chrg.cpMax := fmtRange.chrg.cpMin + richedit1.SelLength - 1;
// format the text
richedit1.Perform( EM_FORMATRANGE, 1, Longint(@fmtRange));
// and print it
richedit1.Perform( EM_DISPLAYBAND, 0, Longint( @fmtRange.rc ));
// Free cached information
richedit1.Perform( EM_FORMATRANGE, 0, 0);
End;
finally
printer.enddoc;
end;
end;
The richedit1.perform( EM_FORMATRANGE call returns the index of the last
character that could be fitted into the passed fmtrange.rc, + 1. So if
multiple pages are required one repeats with fmtrange.chrg.cpMin set to
this value, until the returned character index is richedit1.gettextlen. |
|
