::: 델파이 Tip&Trick :::

델파이 Tip&Trick 성격에 맞지 않는 광고,비방,질문의 글은 즉시 삭제하며
내용을 복사하여 사용할 경우 반드시 이곳(http://www.howto.pe.kr)을 출처로 명시하여 주세요


Category

  김영대(2003-03-06 21:32:09, Hit : 8746, Vote : 2829
 델파이로 DOS 프로그램(Console application) 만들기

// 만드는 방법은 File/New Application 하고 비어있는 폼인 Form1(Unit1) 을
// View/Project Manager 에서 Remove 시킵니다
// 그 다음 View/Project Source 하여 아래 소스를 사용하시면 됩니다
//
// 주) DOS용 프로그램도 윈도우즈용 프로그램의 한 종류일 뿐입니다
//     그래서 아래 소스에서 Windows API를 사용하는 루틴을 보실 수 있습니다

program ConApp;

// 컴퍼일러 지시자
// {$APPTYPE GUI} -> Graphical UI application 생성
// {$APPTYPE CONSOLE} -> CONSOLE application 생성

{$APPTYPE CONSOLE}

uses
  Windows, SysUtils;

const
  // 몇가지 화면의 속성(attribute)
  YellowOnBlue = FOREGROUND_GREEN OR FOREGROUND_RED OR
                 FOREGROUND_INTENSITY OR BACKGROUND_BLUE;
  WhiteOnBlue  = FOREGROUND_BLUE OR FOREGROUND_GREEN OR
                 FOREGROUND_RED OR FOREGROUND_INTENSITY OR
                 BACKGROUND_BLUE;
  RedOnWhite   = FOREGROUND_RED OR FOREGROUND_INTENSITY OR
                 BACKGROUND_RED OR BACKGROUND_GREEN OR BACKGROUND_BLUE
                 OR BACKGROUND_INTENSITY;
  WhiteOnRed   = BACKGROUND_RED OR BACKGROUND_INTENSITY OR
                 FOREGROUND_RED OR FOREGROUND_GREEN OR FOREGROUND_BLUE
                 OR FOREGROUND_INTENSITY;
var
  ConHandle  : THandle; // Handle to console window
  Coord      : TCoord;  // To store/set screen position
  MaxX, MaxY : Word;    // To store max window size
  CCI        : TConsoleCursorInfo;
  NOAW       : LongInt; // To store results of some functions

// Console과 관련된 함수는 GetStdHandle, CreateFile, GetConsoleScreenBufferInfo,
// ReadConsoleInput, SetStdHandle, WriteConsole, WriteFile, GetConsoleCursorInfo,
// SetConsoleCursorPosition, ReadConsole, ReadFile, SetConsoleCursorInfo 를 참고

// console의 표준 입력 버퍼의 핸들(STD_INPUT_HANDLE)을 구한다
function GetConInputHandle: THandle;
begin
  Result := GetStdHandle(STD_INPUT_HANDLE);
end;

// console의 표준 화면 버퍼의 핸들(STD_OUTPUT_HANDLE)을 구한다
function GetConOutputHandle: THandle;
begin
  Result := GetStdHandle(STD_OUTPUT_HANDLE);
end;

// 표준 화면 버퍼의 커서위치를 X, Y
procedure GotoXY(X, Y: Word);
begin
  Coord.X := X; // 수평
  Coord.Y := Y; // 수직
  SetConsoleCursorPosition(ConHandle, Coord);
end;

// 주어진 문자로 표준 화면 버퍼를 채움으로서 화면을 지운다
procedure Cls;
begin
  Coord.X := 0;
  Coord.Y := 0;
  FillConsoleOutputCharacter(ConHandle, ' ', MaxX*MaxY, Coord, NOAW);
  GotoXY(0, 0);
end;

// 화면의 커서를 보이고(True) 감추기(False)
procedure ShowCursor(Show: Bool);
begin
  CCI.bVisible := Show;
  SetConsoleCursorInfo(ConHandle, CCI);
end;

// 변수의 초기화
procedure Init;
begin
  // console의 표준 화면 버퍼의 핸들을 구한다
  ConHandle := GetConOutputHandle;

  // 윈도우의 최대 크기를 구한다
  Coord := GetLargestConsoleWindowSize(ConHandle);
  MaxX := Coord.X;
  MaxY := Coord.Y;
end;

// 표준 화면 버퍼의 (0,0) 좌표에 주어진 문자열을 출력한다
procedure StatusLine(S: String);
begin
  Coord.X := 0;
  Coord.Y := 0;
  // 주어진 좌표(Coord)에 문자열(S)을 출력한다
  WriteConsoleOutputCharacter(ConHandle, PChar(S), Length(S)+1, Coord, NOAW);
  // 주어진 좌표(Coord)와 길이(Length(S))만큼 화면의 속성(WhiteOnRed)을 변경한다
  FillConsoleOutputAttribute(ConHandle, WhiteOnRed, Length(S), Coord, NOAW);
end;

// Console Event Handler
function ConProc(CtrlType: DWord): Bool; stdcall; far;
var
  S: String;
begin
  case CtrlType of
    CTRL_C_EVENT        : S := 'CTRL_C_EVENT'; // CTRL+C
    CTRL_BREAK_EVENT    : S := 'CTRL_BREAK_EVENT'; // CTRL+BREAK
    CTRL_CLOSE_EVENT    : S := 'CTRL_CLOSE_EVENT';
    CTRL_LOGOFF_EVENT   : S := 'CTRL_LOGOFF_EVENT';
    CTRL_SHUTDOWN_EVENT : S := 'CTRL_SHUTDOWN_EVENT';
  else
    S := '알 수 없는 이벤트 발생';
  end;

  MessageBox(0, PChar(S), 'Win32 Console', MB_OK);
  Result := True;
end;

//-------------------------- MAIN ---------------------------
var
  R        : TSmallRect;
  Color    : Word;
  OSVer    : TOSVersionInfo;
  IBuff    : TInputRecord;
  IEvent   : DWord;
  Continue : Bool;
begin
  // 변수의 초기화
  Init;

  // 화면의 윈도우의 위치를 지정
  With R do
  begin
    Left := 10;
    Top  := 10;
    Right  := 40;
    Bottom := 40;
  end;
  SetConsoleWindowInfo(ConHandle, False, R);

  // 이벤트 핸들러(ConProc)를 지정(True)한다
  SetConsoleCtrlHandler(@ConProc, True);

  // console window 의 title bar 를 지정한다
  SetConsoleTitle('콘솔 프로그램');

  ShowCursor(False); // 커서를 감춘다
  Coord.X := 0; Coord.Y := 0;

  Color := WhiteOnBlue; // 파란색 바탕의 힌색글자
  // 주어진 좌표(Coord)와 길이(MaxX*MaxY)만큼 화면의 속성(Coord)을 변경한다
  FillConsoleOutputAttribute(ConHandle, Color, MaxX*MaxY, Coord, NOAW);

  Writeln('Max X=', MaxX,' Max Y=', MaxY);
  Writeln;
  OSVer.dwOSVersionInfoSize := SizeOf(TOSVersionInfo);
  GetVersionEx(OSVer); // Win32 API 를 사용하는 예제
  with OSVer do
  begin
    Writeln('dwMajorVersion = ', dwMajorVersion);
    Writeln('dwMinorVersion = ', dwMinorVersion);
    Writeln('dwBuildNumber  = ', dwBuildNumber);
    Writeln('dwPlatformID   = ', dwPlatformID);
  end;
  Writeln;
  Writeln('Enter키를 누르고 마우스를 움직여 보세요');
  ShowCursor(True); // 커서를 보인다
  Readln; // 사용자 입력을 기다린다(한행 입력)

  // 이벤트 핸들러(ConProc)를 지정을 해제(False)한다
  SetConsoleCtrlHandler(@ConProc, False);
  Cls; // 화면을 지운다

  // Message Loop
  Continue := True;
  while Continue do
  begin
    ReadConsoleInput(GetConInputHandle, IBuff, 1, IEvent);
    // 아래는 처리할 수 있는 이벤트 종류
    //   KEY_EVENT
    //   MOUSE_EVENT
    //   WINDOW_BUFFER_SIZE_EVENT
    //   MENU_EVENT
    //   FOCUS_EVENT
    case IBuff.EventType of
      KEY_EVENT:
      begin
        // 사용자가 ESC 키를 누르면 프로그램을 종료한다
        if ((IBuff.KeyEvent.bKeyDown = True) and
           (IBuff.KeyEvent.wVirtualKeyCode = VK_ESCAPE))
        then
          Continue := False;
      end;
      _MOUSE_EVENT: // 마우스 처리
      begin
        with IBuff.MouseEvent.dwMousePosition do
          StatusLine(Format('%d, %d', [X, Y])); // 마우스 이동시 그 좌표를 출력한다
      end;
    end;
  end
end.





571   [일반/컴포넌트] 레지스트리를 사용하는 사용자 함수 만들어 보기  구창민 2003/03/14 4594 1034
570   [윈도우즈 API] 레지스트리가 변경된 사실을 알리려면...  김영대 2003/03/06 4291 1153
569   [윈도우즈 API] 레지스트리(registry)를 바꾼후...  김영대 2003/03/05 4407 1186
568   [윈도우즈 API] 레지스트리 전체 검색하기  김영대 2003/03/07 3930 1079
567   [윈도우즈 API] 떠있는 모든 Microsoft Internet Explorer 죽이기  김영대 2003/03/29 4467 1262
566   [COM/OLE] 떠있는 모든 Microsoft Internet Explorer 의 html 불러오기  김영대 2003/03/30 5538 1358
565   [COM/OLE] 떠있는 모든 Internet Explorer 를 강제 Refresh 시키기  김영대 2004/09/20 4789 1228
564   [윈도우즈 API] 떠다니는 윈도우  김영대 2003/03/05 4335 1133
563   [시스템] 떠 있는 프로그램 죽이기...  김영대 2003/03/04 5609 1372
562   [시스템] 디스플레이 어댑터 목록 구하기  김영대 2004/08/11 4423 1173
561   [시스템] 디스크의 남은 용량 등등...  김영대 2003/03/05 4972 1348
560   [윈도우즈 API] 디스크 캐쉬의 파일을 디스크로 쓰기  김영대 2003/03/05 4017 1078
559   [시스템] 디스크 드라이브의 현재상태 얻기  김영대 2003/03/05 3442 966
558   [일반/컴포넌트] 디렉토리명 바꾸기/이동 하기  김영대 2003/03/07 4996 1513
557   [윈도우즈 API] 디렉토리나 파일의 속성(변경/생성/사용한 날짜, 특성) 바꾸기  김영대 2004/12/08 9872 1369
556   [일반/컴포넌트] 디렉토리 삭제루틴(하부디렉토리 몽땅)  김영대 2003/03/06 3466 952
555   [일반/컴포넌트] 디렉토리 복사루틴 (하부디렉토리 까지 몽땅)  김영대 2003/03/06 4518 1049
554   [일반/컴포넌트] 디렉토리 변동사항을 탐색기에 알리기  김영대 2003/03/07 5007 1532
553   [일반/컴포넌트] 디렉토리 검색하여 파일 찾기  김영대 2003/03/05 4912 1432
552   [시스템] 드라이브 포맷(Format) API 함수  김영대 2003/03/04 4706 1278
551   [일반/컴포넌트] 둥근 풍선도움말을 나타내주는 콤포넌트  김영대 2003/03/05 3001 731
550   [시스템] 두개의 파일이 완전히 동일한지 검사하기2  김영대 2003/03/07 3207 925
549   [시스템] 두개의 파일이 완전히 동일한지 검사하기(CRC32)  김영대 2003/03/05 4435 1047
548   [일반/컴포넌트] 두개의 StringGrid sync 마추기  김영대 2003/03/07 3523 966
547   [일반/컴포넌트] 두개의 RichEdit 사이에 내용 복사하기  김영대 2003/03/06 5359 1259
546   [알고리즘] 두 문자열의 유사도 검사하기  김영대 2004/09/04 4963 1117
545   [일반/컴포넌트] 두 StringGrid 의 scroll 을 동기화 시키기  김영대 2003/03/07 4254 1027
544   [일반/컴포넌트] 동적으로 프로젝트의 Main form 바꾸기  김영대 2003/04/11 4644 1141
543   [데이터베이스] 동적으로 인덱스 만들기  김영대 2003/03/06 4163 1066
542   [일반/컴포넌트] 동적으로 생성한 TLabel 마우스로 이동시키기  김영대 2004/08/04 6261 1846
541   [일반/컴포넌트] 동적으로 메뉴(memu)에 Item 추가하기  김영대 2003/03/06 4660 1252
540   [데이터베이스] 동적으로 SELECT의 GROUP BY 문 만들기  김영대 2003/03/07 3948 886
539   [일반/컴포넌트] 동적으로 class의 instance 만들기  김영대 2003/03/06 3732 1045
538   [일반/컴포넌트] 도넛(Doughnut) 모양의 폼 만들기  김영대 2004/08/09 4303 1064
537   [윈도우즈 API] 도구모음 Bar는 어떻게 만드는지...  김영대 2003/03/04 4680 1325
536   [일반/컴포넌트] 델파이의 Object Inspector 모방  김영대 2003/03/06 3105 761
535   [윈도우즈 API] 델파이에서 시간을 기다리는 함수  김영대 2003/03/04 5797 1346
534   [일반/컴포넌트] 델파이안에 익스플로러 삽입  신훈재 2003/03/10 5757 1024
  [시스템] 델파이로 DOS 프로그램(Console application) 만들기  김영대 2003/03/06 8746 2829
532   [일반/컴포넌트] 델파이 통합개발환경(IDE) 에 관한 몇가지 Tip  김영대 2003/03/04 5338 1431

[이전 10개] [1].. 11 [12][13][14][15][16][17][18][19][20]..[25] [다음 10개]
 

Copyright 1999-2019 Zeroboard / skin by zero