::: 델파이 Tip&Trick :::

델파이 Tip&Trick 성격에 맞지 않는 광고,비방,질문의 글은 즉시 삭제하며
내용을 복사하여 사용할 경우 반드시 이곳(http://www.howto.pe.kr)을 출처로 명시하여 주세요


Category

  김영대(2003-03-06 22:02:08, Hit : 4164, Vote : 1007
 StringGrid 의 내용을 클립보드로 복사하기

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  StdCtrls, Buttons, clipbrd, Grids;

type
  TForm1 = class(TForm)
    StringGrid1: TStringGrid;
    BitBtn1: TBitBtn;
    Memo1: TMemo;
    procedure FormActivate(Sender: TObject);
    procedure BitBtn1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation
{$R *.DFM}

procedure CopyStreamToClipboard(S: TStream; fmt: Word);
var
  hMem: THandle;
  pMem: Pointer;
begin
  {stream의 위치를 맨 앞으로 이동시킨다}
  S.Position := 0;

  {stream의 크기만큼 전역 힙(heap)에 메모리 블록을 할당한후 윈도우 핸들을 얻는다}
  hMem := GlobalAlloc(GHND or GMEM_DDESHARE, S.Size);
  if hMem <> 0 then
  begin
    {전역 힙의 할당된 메모리 블록을 고정(lock)시킨다}
    pMem := GlobalLock(hMem);
    if pMem <> nil then
    begin
      {할당받은 메모리 블럭에 stream의 내용을 복사한다}
      S.Read(pMem^, S.Size);
      {위의 S.Read()에 의해 증가된 포인터를 다시 맨 앞으로 이동시킨다}
      S.Position := 0;
      {전역 힙에서 메모리 블록의 잠금 해제}
      GlobalUnlock(hMem);

      {클립보드를 열러서 주어진 포맷(여기서는 CF_TEXT)과 윈도우 핸들로 지정된
       데이타를 클립보드에 준다}
      Clipboard.Open;
      try
        Clipboard.SetAsHandle(fmt, hMem);
      finally
        Clipboard.Close;
      end;
    end
    else
    begin
      {메모리 lock의 실패로 memory block 예외를 발생시킨다}
      GlobalFree(hMem);
      OutOfMemoryError;
    end;
  end
  else
  begin
    {메모리 할당의 실패로 memory block 예외를 발생시킨다}
    OutOfMemoryError;
  end;
end;

procedure CopyGridToClipboard(theGrid: TStringGrid);
var
  m: TMemoryStream;
  i, j: Integer;
  S: String;
begin
  m := TMemoryStream.Create;
  try
    with theGrid do
      for i := 0 to Pred(RowCount) {RowCount-1} do
        for j := 0 to Pred(ColCount) {ColCount-1} do
        begin
          S := Cells[j, i];
          if j = Pred(ColCount) then // 맨 마지막 Column이면 CR/LF 를 추가하여 행구분
            AppendStr(S, #13#10)
          else
            AppendStr(S, #9); // 각 Column을 Tab 문자로 구분
          m.WriteBuffer(S[1], Length(S));
        end;
    S[1] := #0; // 문자열 stream의 끝 표시
    m.WriteBuffer(S[1], 1);
    CopyStreamToClipboard(m, CF_TEXT); // stream의 내용을 클립보드로 복사
  finally
    m.Free;
  end;
end;

procedure TForm1.FormActivate(Sender: TObject);
var
  i, j: Integer;
begin
  // Column의 title을 만든다
  for i := 1 to StringGrid1.ColCount - 1 do
   StringGrid1.Cells[i, 0] := Char(Ord('A')+i-1);

  // Row의 title을 만든다
  for i := 1 to StringGrid1.RowCount - 1 do
   StringGrid1.Cells[0, i] := IntToStr(i);;

  // 임의의 자료를 만들어서 각 cell에 입력합니다
  for i := 1 to StringGrid1.ColCount - 1 do
    for j := 1 to StringGrid1.RowCount - 1 do
      StringGrid1.Cells[i, j] := Format('%.0n', [i * j * 10000.0]);
end;

procedure TForm1.BitBtn1Click(Sender: TObject);
begin
  // StringGrid의 내용을 클립보드로 북사
  CopyGridToClipboard(StringGrid1);

  // 클립보드의 내용을 메모로 붙여넣기(테스트용)
  Memo1.Clear;
  Memo1.PasteFromClipboard;
end;

end.





571   [시스템] 마이크 볼륨 조절하기  김영대 2003/03/06 4332 1219
570   [멀티미디어] JPEG, WAVE 를 resource 파일에 넣고 읽어오기  김영대 2003/03/06 4818 1161
569   [일반/컴포넌트] desktop 배경화면을 폼의 배경화면으로 그리기  김영대 2003/03/06 3381 977
568   [윈도우즈 API] 레지스트리의 변경여부 알리는 2가지 방법  김영대 2003/03/06 4445 1162
  [일반/컴포넌트] StringGrid 의 내용을 클립보드로 복사하기  김영대 2003/03/06 4164 1007
566   [데이터베이스] Save DBGrid To Excel  김영대 2003/03/06 5948 1300
565   [COM/OLE] Delphi의 OCX를 InstallShield로 배포하는 방법  김영대 2003/03/06 6261 1549
564   [일반/컴포넌트] ASCII printing  김영대 2003/03/06 4673 1137
563   [일반/컴포넌트] OEM conversion  김영대 2003/03/06 4071 1205
562   [일반/컴포넌트] Memo의 행의 문자수를 제한하고 WordWrap시키기  김영대 2003/03/06 4752 1258
561   [윈도우즈 API] DDE 쓰지 않고 IE의 현재 URL 가져오기  김영대 2003/03/06 5687 1589
560   [윈도우즈 API] RichEdit에 입력한 문장의 실제 높이 구하기  김영대 2003/03/06 4761 1374
559   [일반/컴포넌트] StringGrid 의 선택영역만 클립보드로 복사하기  김영대 2003/03/06 4469 975
558   [일반/컴포넌트] StringGrid 에서 프로그램으로 MultiSelect 시키기  김영대 2003/03/06 4877 1122
557   [윈도우즈 API] 윈도우즈 '시작' 메뉴 Refresh 시키기  김영대 2003/03/07 4384 1362
556   [윈도우즈 API] 다른 Application의 화면에 글자,그림을 출력하기  김영대 2003/03/07 3130 804
555   [일반/컴포넌트] WideString 을 String 으로 바꾸기  김영대 2003/03/07 4226 1004
554   [윈도우즈 API] 윈도우즈 탐색기의 파일, 컴퓨터 찾기 화면 띄우기  김영대 2003/03/07 5875 1571
553   [일반/컴포넌트] MessageDlg()의 폰트를 바꾸어서 띄우기  김영대 2003/03/07 3590 967
552   [일반/컴포넌트] ListView 의 item 을 강제로 편집상태로 만들기  김영대 2003/03/07 4333 1113
551   [데이터베이스] 동적으로 SELECT의 GROUP BY 문 만들기  김영대 2003/03/07 3949 886
550   [윈도우즈 API] ALT_F4 hot key 가로채기  김영대 2003/03/07 5372 1547
549   [윈도우즈 API] 레지스트리 전체 검색하기  김영대 2003/03/07 3930 1079
548   [일반/컴포넌트] TOpenDialog 의 '선택','취소' 버튼 이름 바꾸기  김영대 2003/03/07 4150 1286
547   [윈도우즈 API] 모서리가 둥근(rounded ends) TEdit 만들기  김영대 2003/03/07 4368 1231
546   [시스템] 프로그램이 동적으로 할당받은 메모리 크기 ?  김영대 2003/03/07 4250 1234
545   [일반/컴포넌트] OnActivate 이벤트 내에서 폼 확실히 닫기  김영대 2003/03/07 4006 1035
544   [데이터베이스] Query한 결과를 수정하기...  김영대 2003/03/07 4653 1151
543   [일반/컴포넌트] StringGrid의 Cell을 강제로 다중 선택/해제 시키기  김영대 2003/03/07 3747 958
542   [일반/컴포넌트] TRichEdit의 행간격 띄우기(line spacing)  김영대 2003/03/07 5202 1435
541   [일반/컴포넌트] 프린터로 escape 문자 출력하기(raw print)  김영대 2003/03/07 4574 1091
540   [윈도우즈 API] keyboard, mouse 메시지 무시(skip) 하기  김영대 2003/03/07 4168 1152
539   [윈도우즈 API] 윈도우즈 커서(global cursor) 바꾸기  김영대 2003/03/07 6535 2020
538   [시스템] 현재 프린터의 출력가능한 용지종류 구하기  김영대 2003/03/07 5961 1592
537   [시스템] 프린터에 작업중인 job의 리스트 구하기  김영대 2003/03/07 4493 1183
536   [시스템] Clipboard 훔쳐보기(Clipboard hooking)  김영대 2003/03/07 6523 1525
535   [윈도우즈 API] Control의 repainting 금지하여 깜박임 줄이기  김영대 2003/03/07 4924 1187
534   [일반/컴포넌트] 문자열의 끝에서부터 검색하는 Pos() 함수  김영대 2003/03/07 4909 1118
533   [일반/컴포넌트] 디렉토리명 바꾸기/이동 하기  김영대 2003/03/07 4997 1513
532   [일반/컴포넌트] 디렉토리 변동사항을 탐색기에 알리기  김영대 2003/03/07 5008 1532

[이전 10개] [1].. 11 [12][13][14][15][16][17][18][19][20]..[25] [다음 10개]
 

Copyright 1999-2019 Zeroboard / skin by zero