::: 델파이 Tip&Trick :::

델파이 Tip&Trick 성격에 맞지 않는 광고,비방,질문의 글은 즉시 삭제하며
내용을 복사하여 사용할 경우 반드시 이곳(http://www.howto.pe.kr)을 출처로 명시하여 주세요


Category

  김영대(2003-03-07 20:20:14, Hit : 4322, Vote : 1162
 DOS-matrix 프린터에 인쇄하기

Question:
How do I write a raw string of a data to the printer?

The following unit "PrtRaw.pas" demonstrates a 16/32 bit
raw printing unit for Delphi and Borland C Builder.

Following the unit, is an exmaple on using the
PrtRaw unit.

Notes:

1) You are responsible for embedding all necessary
control codes that the printer may require (including
form feed codes).

2) You must specify a valid printer and port name.



unit PrtRaw;

{Copyright (c) 1998 by Joe C. Hecht - All rights Reserved}
{joehecht@gte.net You may use and share this unit}
{providing my name and the copyright notice stays intact.}

interface

uses
  WinTypes;

{$IFDEF WIN32}
type SpoolInt = DWORD;
{$ELSE}
type SpoolInt = integer;
{$ENDIF}

function StartRawPrintJob(PrinterName : pChar;
                          Port : pChar;
                          DocName : pChar) : THandle;

function StartRawPrintPage(hPrn : THandle) : integer;

function PrintRawData(hPrn : THandle;
                      Buffer : pointer;
                      NumBytes : SpoolInt) : integer;

function EndRawPrintPage(hPrn : THandle) : integer;

function EndRawPrintJob(hPrn : THandle) : integer;


implementation
uses
   WinProcs,
{$IFDEF WIN32}
WinSpool;
{$ELSE}
Print;
{$ENDIF}


function StartRawPrintJob(PrinterName : pChar;
                          Port : pChar;
                          DocName : pChar) : THandle;
{$IFDEF WIN32}
var
   hPrn : THandle;
   DocInfo1 : TDocInfo1;
{$ENDIF}
begin
{$IFDEF WIN32}
   if (OpenPrinter(PChar(PrinterName),
                   hPrn,
                   nil) = FALSE)  then begin
     Result := THandle(-1);
     Exit;
   end;
   DocInfo1.pDocName := DocName;
   DocInfo1.pOutputFile := Port;
   DocInfo1.pDataType := 'RAW';
   if (StartDocPrinter(hPrn,
                       1,
                       @DocInfo1) = 0) then begin
     Result := THandle(-1);
     exit;
   end;
   Result := hPrn;
{$ELSE}
  result := OpenJob(Port,
                    DocName,
                    0);
{$ENDIF}
end;

function StartRawPrintPage(hPrn : THandle) : integer;
begin
{$IFDEF WIN32}
   if (StartPagePrinter(hPrn) = FALSE) then begin
     Result := -1;
     exit;
   end;
   result := 1;
{$ELSE}
  result := StartSpoolPage(hPrn);
{$ENDIF}
end;


function PrintRawData(hPrn : THandle;
                      Buffer : pointer;
                      NumBytes : SpoolInt) : integer;
{$IFDEF WIN32}
var
  BytesWritten : DWORD;
{$ENDIF}
begin
  if (NumBytes = 0) then begin
    Result := 1;
    exit;
  end;
{$IFDEF WIN32}
   if (WritePrinter(hPrn,
                    Buffer,
                    NumBytes,
                    BytesWritten) = FALSE) then begin
     Result := -1;
     exit;
   end;
   if (NumBytes <> BytesWritten) then begin
     Result := -1;
     exit;
   end;
   Result := 1;
{$ELSE}
  result := WriteSpool(hPrn,
                       Buffer,
                       NumBytes);
{$ENDIF}
end;


function EndRawPrintPage(hPrn : THandle) : integer;
begin
{$IFDEF WIN32}
   if (EndPagePrinter(hPrn) = FALSE) then begin
     Result := -1;
     exit;
   end;
   Result := 1;
{$ELSE}
  result := EndSpoolPage(hPrn);
{$ENDIF}
end;


function EndRawPrintJob(hPrn : THandle) : integer;
begin
{$IFDEF WIN32}
   if (EndDocPrinter(hPrn) = FALSE) then begin
     Result := -1;
     exit;
   end;
   if (ClosePrinter(hPrn) = FALSE) then begin
     Result := -1;
     exit;
   end;
   Result := 1;
{$ELSE}
  result := CloseJob(hPrn);
{$ENDIF}
end;


end.

Example of use:

uses
  PrtRaw;


procedure TForm1.Button1Click(Sender: TObject);
var
  hPrn : THandle;
  Data : array[0..31] of char;
begin

  hPrn := StartRawPrintJob('Generic / Text Only',
                           'LPT1:',
                           'My Document');
  if (integer(hPrn) < 0) then begin
    ShowMessage('StartRawPrintJob Failed');
    exit;
  end;

  if (StartRawPrintPage(hPrn) < 0) then begin
    ShowMessage('StartRawPrintPage Failed');
    EndRawPrintJob(hPrn);
    exit;
  end;

  Data[0] := 'P';
  Data[1] := 'a';
  Data[2] := 'g';
  Data[3] := 'e';
  Data[4] := #32;
  Data[5] := '1';
  Data[6] := #13;
  Data[7] := #10;

  if (PrintRawData(hPrn,
                   @data,
                   8) < 0) then begin
    ShowMessage('PrintRawData Failed');
    EndRawPrintPage(hPrn);
    EndRawPrintJob(hPrn);
    exit;
  end;

  if (EndRawPrintPage(hPrn) < 0) then begin
    ShowMessage('EndRawPrintPage Failed');
    EndRawPrintJob(hPrn);
    exit;
  end;

  if (StartRawPrintPage(hPrn) < 0) then begin
    ShowMessage('StartRawPrintPage Failed');
    EndRawPrintJob(hPrn);
    exit;
  end;
  Data[0] := 'P';
  Data[1] := 'a';
  Data[2] := 'g';
  Data[3] := 'e';
  Data[4] := #32;
  Data[5] := '2';
  Data[6] := #13;
  Data[7] := #10;

  if (PrintRawData(hPrn,
                   @data,
                   8) < 0) then begin
    ShowMessage('PrintRawData Failed');
    EndRawPrintPage(hPrn);
    EndRawPrintJob(hPrn);
    exit;
  end;

  if (EndRawPrintPage(hPrn) < 0) then begin
    ShowMessage('EndRawPrintPage Failed');
    EndRawPrintJob(hPrn);
    exit;
  end;

  if (EndRawPrintJob(hPrn) < 0) then begin
    ShowMessage('EndRawPrintJob Failed');
    exit;
  end;

end;

end.





571   [일반/컴포넌트] 전각문자인지 반각문자인지 검사하기  김영대 2003/03/07 5516 1170
570   [시스템] 폴더의 변경여부를 감시하기  김영대 2003/03/07 5177 1222
569   [윈도우즈 API] 스크린 세이버의 기동시간 바꾸기  김영대 2003/03/07 4140 1253
568   [일반/컴포넌트] 간단히 화면 하드카피(snapshot) 하기  김영대 2003/03/07 4609 1103
567   [데이터베이스] 데이타베이스 로그인(login) 화면 띄우기  김영대 2003/03/07 3928 971
566   [윈도우즈 API] 커서(케럿)의 깜박임 속도를 변경하기  김영대 2003/03/07 4463 1215
565   [데이터베이스] SQL실행시의 모래시계를 표시하지 않는 방법  김영대 2003/03/07 4411 1105
564   [시스템] 윈도우즈 전체의 키보드 입력 금지  김영대 2003/03/07 4341 1163
563   [윈도우즈 API] TaskBar의 다양한 기능제어  김영대 2003/03/07 4971 1338
562   [윈도우즈 API] 윈도우즈"시작" 버튼 Disable/Enable  김영대 2003/03/07 4382 1156
561   [일반/컴포넌트] 윈도우즈 메모장의 편집내용을 가져오기  김영대 2003/03/07 3816 1033
560   [일반/컴포넌트] ListBox의 화면에 보여지는 최상위 Item 번호  김영대 2003/03/07 4136 1124
559   [네트웍/인터넷] Getting Novell Netware Login NAME  김영대 2003/03/07 3269 904
558   [윈도우즈 API] Window Handle 로 실행파일명 구하기  김영대 2003/03/07 4509 1165
557   [네트웍/인터넷] 인터넷에 LAN 또는 Modem으로 접속중인지 검사  김영대 2003/03/07 4731 1238
556   [윈도우즈 API] 작업관리자의 task switching 금지시키기  김영대 2003/03/07 4467 1168
555   [COM/OLE] 윈도우즈 시작의 "실행" 화면 띄우기  김영대 2003/03/07 3832 1075
554   [윈도우즈 API] How to flush key buffer  김영대 2003/03/07 4266 1132
553   [일반/컴포넌트] 숫자의 근사치 구하기  김영대 2003/03/07 3990 1063
552   [시스템] CPU의 사용률 구하기  김영대 2003/03/07 4653 1225
551   [시스템] drive의 일련번호 바꾸기  김영대 2003/03/07 6284 1476
550   [윈도우즈 API] Application의 최소화시 Zooming 효과 주기2  김영대 2003/03/07 5236 1363
549   [네트웍/인터넷] NetMask 알아내기  김영대 2003/03/07 7002 1797
548   [일반/컴포넌트] TRichEdit를 사용한 syntax highlighting 예제  김영대 2003/03/07 6355 1688
547   [일반/컴포넌트] 텍스트 파일 합치기(Merging)  김영대 2003/03/07 4711 1071
546   [네트웍/인터넷] 네트워크 컴퓨터가 존재하는지 검사하기  김영대 2003/03/07 4744 1206
545   [일반/컴포넌트] RichEdit 화면에 보여지는 첫번째/마지막 행번호  김영대 2003/03/07 5193 1384
544   [윈도우즈 API] 모든 창을 아이콘 표시/취소  김영대 2003/03/07 4065 1172
543   [윈도우즈 API] 윈도우즈 "시작" 메뉴를 내 프로그램 안으로...  김영대 2003/03/07 4419 1197
  [시스템] DOS-matrix 프린터에 인쇄하기  김영대 2003/03/07 4322 1162
541   [윈도우즈 API] IE의 현재 url 가져오기  김영대 2003/03/07 4398 1102
540   [네트웍/인터넷] Serial Port 사용하기  김영대 2003/03/07 6538 1702
539   [네트웍/인터넷] Ethernet 랜카드의 MAC adress 구하기  김영대 2003/03/07 7080 1843
538   [시스템] reboot 95/98/NT  김영대 2003/03/07 4305 1237
537   [일반/컴포넌트] TIFF Images and manipulation  김영대 2003/03/07 4615 1114
536   [네트웍/인터넷] LAN 에 접속했는지 검사하기  김영대 2003/03/07 4293 1138
535   [시스템] CPU speed 구하기 2  김영대 2003/03/07 3954 1121
534   [시스템] 일정시간 경과후 없어지는 MessageBox  김영대 2003/03/07 6330 1299
533   [시스템] 파일이 다른 프로그램에 의해 사용중인지 검사  김영대 2003/03/07 5622 1280
532   [일반/컴포넌트] 윈도우즈 파일명의 무효한 구성문자  김영대 2003/03/07 4508 1426

[이전 10개] [1].. 11 [12][13][14][15][16][17][18][19][20]..[25] [다음 10개]
 

Copyright 1999-2019 Zeroboard / skin by zero