::: 델파이 Tip&Trick :::

델파이 Tip&Trick 성격에 맞지 않는 광고,비방,질문의 글은 즉시 삭제하며
내용을 복사하여 사용할 경우 반드시 이곳(http://www.howto.pe.kr)을 출처로 명시하여 주세요


Category

  김영대(2003-03-07 20:51:46, Hit : 5309, Vote : 1244
 프린터 리스트를 구하여 기본 프린터 변경하기

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  StdCtrls, WinSpool, IniFiles;

type
  TForm1 = class(TForm)
    Button1: TButton;
    ListBox1: TListBox;
    Memo1: TMemo;
    procedure FormActivate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure ListBox1Click(Sender: TObject);
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
    pEnumDriversData: PDriverInfo2;
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation
{$R *.DFM}

procedure TForm1.FormActivate(Sender: TObject);
var
  i, bytesNeeded: DWORD;
  pTemp: PDriverInfo2;
  NumDrivers: DWORD;
begin
  Listbox1.Clear;
  if Assigned(pEnumDriversData) Then
    FreeMem(pEnumDriversData);

  // 설치된 모든 프린터 드라이브 갯수를 구한다
  Numdrivers := 0;
  bytesNeeded := 0;
  EnumPrinterDrivers(nil, nil, 2, Nil, 0, bytesNeeded, NumDrivers); // 2번 정보
  if bytesNeeded = 0 then
  begin
    ShowMEssage('설치된 프린터 드라이브가 없습니다');
    System.Exit;
  end;

  // 정보를 저장할 메모리를 만든다
  GetMem(pEnumDriversData, bytesNeeded);
  // 설치된 모든 프린터 드라이브 정보(2번)를 구한다
  // 서버명이 생략되었으므로 내 PC의 드라이버를 읽는다
  if EnumPrinterDrivers(nil, nil, 2, pEnumDriversData, bytesNeeded,
                        bytesNeeded, NumDrivers) then
  begin
    pTemp := pEnumDriversData;
    for i:= 1 to Numdrivers do
    begin
      // 드라이버명과 스트럭쳐의 시작 포인터를 Object로 ListBox에 추가한다
      Listbox1.Items.AddObject(pTemp^.pName, TObject(pTemp));
      // 다음 드라이버 정보의 스트럭쳐로 포인터를 이동시킨다
      // Note: Inc increments a pointer by the size of its base type!
      Inc(pTemp);
    end;
    Listbox1.ItemIndex := 0;
    Listbox1Click(Listbox1);
  end
  else
    RaiseLastWin32Error;
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  if Assigned(pEnumDriversData) then
    FreeMem(pEnumDriversData);
end;

// 선택한 프린터의 정보를 Memo에 출력한다
procedure TForm1.ListBox1Click(Sender: TObject);
var
  pTemp: PDriverInfo2;
begin
  with Sender as TListbox do
  begin
    if ItemIndex >= 0 then
    begin
      Memo1.Clear;
      pTemp:= PDriverInfo2(Items.Objects[ItemIndex]);
      with Memo1.Lines, pTemp^ do
      begin
        Add(Format('Version:'#9#9'%d',   [cVersion]));
        Add(Format('Name:'#9#9'%s',      [pName]));
        Add(Format('Environment:'#9'%s', [pEnvironment]));
        Add(Format('DriverPath:'#9'%s',  [pDriverPath]));
        Add(Format('DataFile:'#9#9'%s',  [pDataFile]));
        Add(Format('ConfigFile:'#9'%s',  [pConfigFile]));
      end;
    end;
  end;
end;

// 선택한 프린터를 기본 프린터로 설정한다
procedure TForm1.Button1Click(Sender: TObject);
var
  pTemp: PDriverInfo2;
  WinIni: TIniFile;
  WinIniFileName: array[0..MAX_PATH] of char;
  s: array[0..64] of char;
  DirverName: String;
begin
  if ListBox1.ItemIndex >= 0 then
  begin
    pTemp:= PDriverInfo2(ListBox1.Items.Objects[ListBox1.ItemIndex]);
    DirverName := Copy(DirverName,1,Length(DirverName)-Length(ExtractFileExt(DirverName)));

    // Windows.ini 파일의 "Windows" 섹션에 "printer, driver, port" 를
    // 지정하여 기본프린터를 바꾼다
    // 이때 기본프린터 변경여부를 다른 애플리케이션들에게
    // 알리기 위해 WM_WININICHANGE 메시지를 BroadCast 한다
    GetWindowsDirectory(WinIniFileName, sizeof(WinIniFileName));
    StrCat(WinIniFileName, 'win.ini');
    WinIni := TIniFile.Create(WinIniFileName);
    WinIni.WriteString('windows',
                       'device',
                       StrPas(pTemp^.pName)+','+ // 프린터명
                       DirverName+',LPT1:'); // 드리아버명, 포트
    WinIni.Free;
    StrCopy(S, 'windows');
    SendMessage(HWND_BROADCAST, WM_WININICHANGE, 0, LongInt(@S));

    ShowMessage('기본 프린터를 "'+StrPas(pTemp^.pName)+'"로 변경하였숩니다');
  end;
end;

end.





611   [윈도우즈 API] DDE를 사용하여 IE, Netscape의 현재 URL 가져오기  김영대 2003/03/07 4569 1238
610   [윈도우즈 API] 데스크탑에 있는 아이콘의 갯수 구하기  김영대 2003/03/07 4180 1144
609   [일반/컴포넌트] design mode 인지 검사하기  김영대 2003/03/07 5725 1463
608   [네트웍/인터넷] 프린터의 용지 크기/공급 설정하기  김영대 2003/03/07 6925 1272
607   [시스템] 프린터의 "용지 공급" 리스트 구하기  김영대 2003/03/07 4690 1351
606   [네트웍/인터넷] Read/Write to COM Port  김영대 2003/03/07 4823 1143
605   [일반/컴포넌트] Button의 Mouse Down/Up 흉내내기  김영대 2003/03/07 4357 1126
604   [일반/컴포넌트] 두 StringGrid 의 scroll 을 동기화 시키기  김영대 2003/03/07 4407 1071
603   [일반/컴포넌트] 해상도(screen resolution)를 변경했는지 검사  김영대 2003/03/07 4592 1298
602   [일반/컴포넌트] StringGrid의 선택된 Cell을 버튼으로 보이기  김영대 2003/03/07 4397 1091
601   [윈도우즈 API] Windows NT 도메인명 가져오기  김영대 2003/03/07 5638 1486
600   [시스템] Locking/ Unlocking floppy driver or CD  김영대 2003/03/07 4186 1185
599   [시스템] CD-ROM의 변경여부를 감시하기  김영대 2003/03/07 4905 1277
598   [윈도우즈 API] 즐겨찾기 폴더의 파일에서 URL 뽑아내기  김영대 2003/03/07 5144 1260
597   [데이터베이스] Record Lock 검사  김영대 2003/03/07 4206 1092
596   [일반/컴포넌트] Delphi 4 Secret Registry Settings  김영대 2003/03/07 6299 1547
595   [일반/컴포넌트] ListView 의 column header 오른쪽에 이미지 넣기  김영대 2003/03/07 4845 1176
594   [시스템] 윈도우즈 캡션의 높이 읽기/설정  김영대 2003/03/07 4358 1186
593   [시스템] 키보드 자동반복속도 읽기/설정  김영대 2003/03/07 5352 1456
592   [시스템] 키보드 자동반복지연 읽기/설정  김영대 2003/03/07 4567 1156
591   [일반/컴포넌트] 베쥬(Bezier) 곡선 그리기2  김영대 2003/03/07 4681 1117
590   [윈도우즈 API] CTRL+ALT+DEL 에 나타나지 않는 프로그램  김영대 2003/03/07 5023 1259
589   [시스템] Delphi VCL 사용안하고 프로그램 만들기  김영대 2003/03/07 5121 1264
588   [일반/컴포넌트] 부활절 달걀(easter egg) 문자열 입력받기  김영대 2003/03/07 4635 1075
587   [윈도우즈 API] 정의되지 않은 Alt+키 입력시 Beep음 제거  김영대 2003/03/07 4260 1189
586   [일반/컴포넌트] 베쥬(Bezier) 곡선 그리기  김영대 2003/03/07 4713 1404
585   [윈도우즈 API] 바탕화면 아이콘의 글자색 바꾸기2  김영대 2003/03/07 5080 1432
584   [시스템] 프린트 스풀러 제어방법  김영대 2003/03/07 6415 1809
583   [네트웍/인터넷] Network Adaptor 가 여러개인 경우의 IP 구하기  김영대 2003/03/07 6134 1528
582   [일반/컴포넌트] 파일에서 특정 Byte 모두 찾기  김영대 2003/03/07 4415 1124
581   [윈도우즈 API] 스크린 세이버 비밀번호 알아내기  김영대 2003/03/07 4796 1171
580   [윈도우즈 API] 바탕화면 아이콘의 글자색 바꾸기  김영대 2003/03/07 5046 1261
579   [일반/컴포넌트] StringGrid 의 BeginUpdate/EndUpdate ?  김영대 2003/03/07 5282 1138
578   [시스템] 시스템에 등록된 한글폰트의 리스트  김영대 2003/03/07 5120 1511
577   [윈도우즈 API] 폼을 최하위(?)로 설정하기  김영대 2003/03/07 4660 1241
576   [일반/컴포넌트] 타이틀바 클릭시 사용자 팝업메뉴 보이기  김영대 2003/03/07 4773 1147
  [시스템] 프린터 리스트를 구하여 기본 프린터 변경하기  김영대 2003/03/07 5309 1244
574   [데이터베이스] DBGrid의 수직이동 막대 감추기  김영대 2003/03/07 4660 1204
573   [일반/컴포넌트] 임시파일명 자동으로 생성하기  김영대 2003/03/07 5124 1628
572   [일반/컴포넌트] 문자열의 바이트수가 아닌 실제 글자수 구하기  김영대 2003/03/07 4839 1105

[1][2][3][4][5][6][7][8][9] 10 ..[25] [다음 10개]
 

Copyright 1999-2021 Zeroboard / skin by zero