::: 델파이 Tip&Trick :::

델파이 Tip&Trick 성격에 맞지 않는 광고,비방,질문의 글은 즉시 삭제하며
내용을 복사하여 사용할 경우 반드시 이곳(http://www.howto.pe.kr)을 출처로 명시하여 주세요


Category

  김영대(2003-03-06 21:32:09, Hit : 14090, Vote : 7518
 델파이로 DOS 프로그램(Console application) 만들기

// 만드는 방법은 File/New Application 하고 비어있는 폼인 Form1(Unit1) 을
// View/Project Manager 에서 Remove 시킵니다
// 그 다음 View/Project Source 하여 아래 소스를 사용하시면 됩니다
//
// 주) DOS용 프로그램도 윈도우즈용 프로그램의 한 종류일 뿐입니다
//     그래서 아래 소스에서 Windows API를 사용하는 루틴을 보실 수 있습니다

program ConApp;

// 컴퍼일러 지시자
// {$APPTYPE GUI} -> Graphical UI application 생성
// {$APPTYPE CONSOLE} -> CONSOLE application 생성

{$APPTYPE CONSOLE}

uses
  Windows, SysUtils;

const
  // 몇가지 화면의 속성(attribute)
  YellowOnBlue = FOREGROUND_GREEN OR FOREGROUND_RED OR
                 FOREGROUND_INTENSITY OR BACKGROUND_BLUE;
  WhiteOnBlue  = FOREGROUND_BLUE OR FOREGROUND_GREEN OR
                 FOREGROUND_RED OR FOREGROUND_INTENSITY OR
                 BACKGROUND_BLUE;
  RedOnWhite   = FOREGROUND_RED OR FOREGROUND_INTENSITY OR
                 BACKGROUND_RED OR BACKGROUND_GREEN OR BACKGROUND_BLUE
                 OR BACKGROUND_INTENSITY;
  WhiteOnRed   = BACKGROUND_RED OR BACKGROUND_INTENSITY OR
                 FOREGROUND_RED OR FOREGROUND_GREEN OR FOREGROUND_BLUE
                 OR FOREGROUND_INTENSITY;
var
  ConHandle  : THandle; // Handle to console window
  Coord      : TCoord;  // To store/set screen position
  MaxX, MaxY : Word;    // To store max window size
  CCI        : TConsoleCursorInfo;
  NOAW       : LongInt; // To store results of some functions

// Console과 관련된 함수는 GetStdHandle, CreateFile, GetConsoleScreenBufferInfo,
// ReadConsoleInput, SetStdHandle, WriteConsole, WriteFile, GetConsoleCursorInfo,
// SetConsoleCursorPosition, ReadConsole, ReadFile, SetConsoleCursorInfo 를 참고

// console의 표준 입력 버퍼의 핸들(STD_INPUT_HANDLE)을 구한다
function GetConInputHandle: THandle;
begin
  Result := GetStdHandle(STD_INPUT_HANDLE);
end;

// console의 표준 화면 버퍼의 핸들(STD_OUTPUT_HANDLE)을 구한다
function GetConOutputHandle: THandle;
begin
  Result := GetStdHandle(STD_OUTPUT_HANDLE);
end;

// 표준 화면 버퍼의 커서위치를 X, Y
procedure GotoXY(X, Y: Word);
begin
  Coord.X := X; // 수평
  Coord.Y := Y; // 수직
  SetConsoleCursorPosition(ConHandle, Coord);
end;

// 주어진 문자로 표준 화면 버퍼를 채움으로서 화면을 지운다
procedure Cls;
begin
  Coord.X := 0;
  Coord.Y := 0;
  FillConsoleOutputCharacter(ConHandle, ' ', MaxX*MaxY, Coord, NOAW);
  GotoXY(0, 0);
end;

// 화면의 커서를 보이고(True) 감추기(False)
procedure ShowCursor(Show: Bool);
begin
  CCI.bVisible := Show;
  SetConsoleCursorInfo(ConHandle, CCI);
end;

// 변수의 초기화
procedure Init;
begin
  // console의 표준 화면 버퍼의 핸들을 구한다
  ConHandle := GetConOutputHandle;

  // 윈도우의 최대 크기를 구한다
  Coord := GetLargestConsoleWindowSize(ConHandle);
  MaxX := Coord.X;
  MaxY := Coord.Y;
end;

// 표준 화면 버퍼의 (0,0) 좌표에 주어진 문자열을 출력한다
procedure StatusLine(S: String);
begin
  Coord.X := 0;
  Coord.Y := 0;
  // 주어진 좌표(Coord)에 문자열(S)을 출력한다
  WriteConsoleOutputCharacter(ConHandle, PChar(S), Length(S)+1, Coord, NOAW);
  // 주어진 좌표(Coord)와 길이(Length(S))만큼 화면의 속성(WhiteOnRed)을 변경한다
  FillConsoleOutputAttribute(ConHandle, WhiteOnRed, Length(S), Coord, NOAW);
end;

// Console Event Handler
function ConProc(CtrlType: DWord): Bool; stdcall; far;
var
  S: String;
begin
  case CtrlType of
    CTRL_C_EVENT        : S := 'CTRL_C_EVENT'; // CTRL+C
    CTRL_BREAK_EVENT    : S := 'CTRL_BREAK_EVENT'; // CTRL+BREAK
    CTRL_CLOSE_EVENT    : S := 'CTRL_CLOSE_EVENT';
    CTRL_LOGOFF_EVENT   : S := 'CTRL_LOGOFF_EVENT';
    CTRL_SHUTDOWN_EVENT : S := 'CTRL_SHUTDOWN_EVENT';
  else
    S := '알 수 없는 이벤트 발생';
  end;

  MessageBox(0, PChar(S), 'Win32 Console', MB_OK);
  Result := True;
end;

//-------------------------- MAIN ---------------------------
var
  R        : TSmallRect;
  Color    : Word;
  OSVer    : TOSVersionInfo;
  IBuff    : TInputRecord;
  IEvent   : DWord;
  Continue : Bool;
begin
  // 변수의 초기화
  Init;

  // 화면의 윈도우의 위치를 지정
  With R do
  begin
    Left := 10;
    Top  := 10;
    Right  := 40;
    Bottom := 40;
  end;
  SetConsoleWindowInfo(ConHandle, False, R);

  // 이벤트 핸들러(ConProc)를 지정(True)한다
  SetConsoleCtrlHandler(@ConProc, True);

  // console window 의 title bar 를 지정한다
  SetConsoleTitle('콘솔 프로그램');

  ShowCursor(False); // 커서를 감춘다
  Coord.X := 0; Coord.Y := 0;

  Color := WhiteOnBlue; // 파란색 바탕의 힌색글자
  // 주어진 좌표(Coord)와 길이(MaxX*MaxY)만큼 화면의 속성(Coord)을 변경한다
  FillConsoleOutputAttribute(ConHandle, Color, MaxX*MaxY, Coord, NOAW);

  Writeln('Max X=', MaxX,' Max Y=', MaxY);
  Writeln;
  OSVer.dwOSVersionInfoSize := SizeOf(TOSVersionInfo);
  GetVersionEx(OSVer); // Win32 API 를 사용하는 예제
  with OSVer do
  begin
    Writeln('dwMajorVersion = ', dwMajorVersion);
    Writeln('dwMinorVersion = ', dwMinorVersion);
    Writeln('dwBuildNumber  = ', dwBuildNumber);
    Writeln('dwPlatformID   = ', dwPlatformID);
  end;
  Writeln;
  Writeln('Enter키를 누르고 마우스를 움직여 보세요');
  ShowCursor(True); // 커서를 보인다
  Readln; // 사용자 입력을 기다린다(한행 입력)

  // 이벤트 핸들러(ConProc)를 지정을 해제(False)한다
  SetConsoleCtrlHandler(@ConProc, False);
  Cls; // 화면을 지운다

  // Message Loop
  Continue := True;
  while Continue do
  begin
    ReadConsoleInput(GetConInputHandle, IBuff, 1, IEvent);
    // 아래는 처리할 수 있는 이벤트 종류
    //   KEY_EVENT
    //   MOUSE_EVENT
    //   WINDOW_BUFFER_SIZE_EVENT
    //   MENU_EVENT
    //   FOCUS_EVENT
    case IBuff.EventType of
      KEY_EVENT:
      begin
        // 사용자가 ESC 키를 누르면 프로그램을 종료한다
        if ((IBuff.KeyEvent.bKeyDown = True) and
           (IBuff.KeyEvent.wVirtualKeyCode = VK_ESCAPE))
        then
          Continue := False;
      end;
      _MOUSE_EVENT: // 마우스 처리
      begin
        with IBuff.MouseEvent.dwMousePosition do
          StatusLine(Format('%d, %d', [X, Y])); // 마우스 이동시 그 좌표를 출력한다
      end;
    end;
  end
end.





611   [데이터베이스] DB에 저장된 JPEG(JPG)를 DBGrid에 출력하기  김영대 2003/03/06 5217 1252
610   [데이터베이스] 동적으로 인덱스 만들기  김영대 2003/03/06 4424 1126
609   [데이터베이스] Excel ODBC를 사용하여 xls를 테이블로 사용하기  김영대 2003/03/06 6804 1575
608   [데이터베이스] DB alias중 ORACLE alias 명 구하기  김영대 2003/03/06 3981 970
607   [일반/컴포넌트] QuickReport에서 프린터 바꾸어서 출력하기  김영대 2003/03/06 6175 1535
606   [일반/컴포넌트] RichEdit 의 내용을 Bitmap 으로 만들기  김영대 2003/03/06 3324 864
605   [일반/컴포넌트] RichEdit 에서 문자(열)를 찾아 글자속성 바꾸기  김영대 2003/03/06 4698 1210
604   [일반/컴포넌트] RichEdit 에서 커서를 처음, 마지막으로 보내기  김영대 2003/03/06 6828 1473
603   [윈도우즈 API] 실행중인 모든 프로그램 Minimized 시키기  김영대 2003/03/06 4631 1226
  [시스템] 델파이로 DOS 프로그램(Console application) 만들기  김영대 2003/03/06 14090 7518
601   [COM/OLE] Registering *.tlb files without Delphi  김영대 2003/03/06 4937 1128
600   [네트웍/인터넷] How to bring a network down - "Win Nuke"  김영대 2003/03/06 7261 1991
599   [윈도우즈 API] 폴더나 파일의 윈도우즈 등록정보 dialog 띄우기  김영대 2003/03/06 5070 1473
598   [일반/컴포넌트] 이미지를 마우스로 drag 해서 zoom 하기  김영대 2003/03/06 3585 1019
597   [윈도우즈 API] 외부 프로그램을 최상위로 설정하기  김영대 2003/03/06 5191 1227
596   [일반/컴포넌트] TObject의 프로퍼티를 문자열로 참조하기  김영대 2003/03/06 5206 1591
595   [윈도우즈 API] 프로그램으로 Screensaver 등록하는 두가지 방법  김영대 2003/03/06 4460 1267
594   [데이터베이스] 특정 폼의 현재 편집중인 DB Field 구하기  김영대 2003/03/06 4067 1110
593   [윈도우즈 API] KeyDown의 Beep음을 없애자...  김영대 2003/03/06 4586 1210
592   [시스템] How do I use SetWindowsHookEx ?  김영대 2003/03/06 6758 954
591   [시스템] Redirecting DOS Application Output  김영대 2003/03/06 4467 1201
590   [일반/컴포넌트] 두개의 RichEdit 사이에 내용 복사하기  김영대 2003/03/06 5816 1360
589   [일반/컴포넌트] 특정 Color의 Invert Color 구하기  김영대 2003/03/06 4299 1315
588   [일반/컴포넌트] 문자열 수식문장(expression)의 결과 구하기  김영대 2003/03/06 3260 868
587   [시스템] 오디오 CD의 볼륨 조절하기  김영대 2003/03/06 3584 1025
586   [일반/컴포넌트] 윈도우즈 "날짜/시간" 설정화면 띄우기  김영대 2003/03/06 6178 1822
585   [시스템] 마이크 볼륨 조절하기  김영대 2003/03/06 4596 1284
584   [멀티미디어] JPEG, WAVE 를 resource 파일에 넣고 읽어오기  김영대 2003/03/06 5206 1223
583   [일반/컴포넌트] desktop 배경화면을 폼의 배경화면으로 그리기  김영대 2003/03/06 3645 1037
582   [윈도우즈 API] 레지스트리의 변경여부 알리는 2가지 방법  김영대 2003/03/06 4727 1277
581   [일반/컴포넌트] StringGrid 의 내용을 클립보드로 복사하기  김영대 2003/03/06 4433 1060
580   [데이터베이스] Save DBGrid To Excel  김영대 2003/03/06 6660 1721
579   [COM/OLE] Delphi의 OCX를 InstallShield로 배포하는 방법  김영대 2003/03/06 6725 5613
578   [일반/컴포넌트] ASCII printing  김영대 2003/03/06 5103 1209
577   [일반/컴포넌트] OEM conversion  김영대 2003/03/06 4291 1261
576   [일반/컴포넌트] Memo의 행의 문자수를 제한하고 WordWrap시키기  김영대 2003/03/06 5175 1314
575   [윈도우즈 API] DDE 쓰지 않고 IE의 현재 URL 가져오기  김영대 2003/03/06 5958 1670
574   [윈도우즈 API] RichEdit에 입력한 문장의 실제 높이 구하기  김영대 2003/03/06 5017 1426
573   [일반/컴포넌트] StringGrid 의 선택영역만 클립보드로 복사하기  김영대 2003/03/06 4818 1045
572   [일반/컴포넌트] StringGrid 에서 프로그램으로 MultiSelect 시키기  김영대 2003/03/06 5360 1187

[1][2][3][4][5][6][7][8][9] 10 ..[25] [다음 10개]
 

Copyright 1999-2022 Zeroboard / skin by zero