::: 델파이 Tip&Trick :::

델파이 Tip&Trick 성격에 맞지 않는 광고,비방,질문의 글은 즉시 삭제하며
내용을 복사하여 사용할 경우 반드시 이곳(http://www.howto.pe.kr)을 출처로 명시하여 주세요


Category

  김영대(2004-09-29 21:57:24, Hit : 6732, Vote : 1385
 http://www.howto.pe.kr
 DOS 명령어 실행하고 실시간 결과 받아오기

// DOS 명령어 실행하고 결과 받아오는 일반적인 예제들은 DOS 명령어의 실행이
// 끝난 후 화면 출력을 보여주지만 아래 예제는 DOS 명령어를 실행하고 발생하는
// 화면 출력을 바로바로 출력하는 실시간성 캡쳐 예제입니다

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Memo1: TMemo;
    Edit1: TEdit;
    procedure Button1Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure GetDosOutput(cmd: String; OutputMemo: TMemo);
const
  BufSize = $4000;

type
  TPipeHandles = record
    hRead,
    hWrite: DWORD;
  end;

  procedure ClosePipe(var Pipe: TPipeHandles);
  begin
    with Pipe do
    begin
      if hRead <> 0 then CloseHandle (hRead);
      if hWrite <> 0 then CloseHandle (hWrite);
      hRead := 0;
      hWrite := 0;
    end;
  end;

  procedure ReadPipe(var Pipe: TPipeHandles);
  var
    ReadBuf: array[0..BufSize] of Char;
    BytesRead: Dword;
  begin
    // 파이프에 읽을 데이터가 있는지 검사
    if PeekNamedPipe(Pipe.hRead, nil, 0, nil, @BytesRead, nil) and
      (BytesRead > 0) then // 읽을 데이터가 있다
    begin
      ReadFile(Pipe.hRead, ReadBuf, BytesRead, BytesRead, nil);
      if BytesRead > 0 then
      begin
        ReadBuf[BytesRead] := #0;
        OutputMemo.SelText := ReadBuf;
        OutputMemo.Perform(EM_SCROLLCARET, 0, 0);
      end;
    end;
  end;

var
  ProcessInfo: TProcessInformation;
  StartupInfo: TStartupInfo;
  SecAttr: TSecurityAttributes;
  PipeStdOut: TPipeHandles;
  PipeStdErr: TPipeHandles;
  dwExitCode: DWORD;

begin
  SecAttr.nLength := SizeOf(SecAttr);
  SecAttr.lpSecurityDescriptor := nil;
  SecAttr.bInheritHandle := TRUE;

  with PipeStdOut do // 표준 출력(stdout) 파이프
    if not CreatePipe (hRead, hWrite, @SecAttr, BufSize) then
      ShowMessage('STDOUT pipe 를 만들 수 없습니다');

  try
    with PipeStdErr do // 표준 에러(stderr) 파이프
      if not CreatePipe (hRead, hWrite, @SecAttr, BufSize) then
        ShowMessage('STDERR pipe 를 만들 수 없습니다');
  except
    ClosePipe(PipeStdOut);
    raise;
    exit;
  end;

  try
    FillChar(StartupInfo,SizeOf(StartupInfo), 0);
    with StartupInfo do
    begin
      cb          := SizeOf(StartupInfo);
      dwFlags     := STARTF_USESHOWWINDOW or STARTF_USESTDHANDLES;
      hStdOutput  := PipeStdOut.hWrite;
      hStdError   := PipeStdErr.hWrite;
      wShowWindow := SW_HIDE;
    end;

    if CreateProcess(
        nil, PChar(Cmd), @SecAttr, @SecAttr, true,
        DETACHED_PROCESS or NORMAL_PRIORITY_CLASS,
        nil, nil,
        StartupInfo, ProcessInfo) then
    begin
      dwExitCode := STILL_ACTIVE;
      Screen.Cursor := crHourglass;
      try
        repeat
          // 두번쨰 파라미터가 0이면 즉시 리턴
          WaitForSingleObject(ProcessInfo.hProcess, 0);
          GetExitCodeProcess(ProcessInfo.hProcess, dwExitCode);

          Application.ProcessMessages;

          ReadPipe(PipeStdOut);
          ReadPipe(PipeStdErr);
        until dwExitCode <> STILL_ACTIVE; // 아직 실행중이면 반복

        if not GetExitCodeProcess(ProcessInfo.hProcess, dwExitCode) then
         ShowMessage('exit code 를 읽어올 수 없습니다');

        if dwExitCode <> 0 then // 정상 종료가 아니면...
          raise Exception.Create('Exit code ' + IntToStr(dwExitCode));

      finally
        Screen.Cursor := crDefault;
        if dwExitCode = STILL_ACTIVE then
          TerminateProcess(ProcessInfo.hProcess, 1);
        CloseHandle(ProcessInfo.hProcess);
        CloseHandle(ProcessInfo.hThread);
        ProcessInfo.hProcess := 0;
      end;
    end
    else
      ShowMessage(Cmd+' 명령어 실행을 위한 프로세스 생성 실패');

  finally
   ClosePipe(PipeStdOut);
   ClosePipe(PipeStdErr);
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  Memo1.Clear;
  GetDosOutput(Edit1.Text, Memo1);
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  // 실행할 DOS 명령어
  Edit1.Text := 'ping www.howto.pe.kr';
end;

end.





971   [시스템] 사용중인 USB 포트의 장치정보 구하기  김영대 2008/11/04 18336 1505
970   [윈도우즈 API] ShellExecute(Ex) 사용법 예제 12가지  김영대 2004/09/22 16956 1681
969   [시스템] 원도우즈 도메인 이름 구하기  김영대 2008/11/04 12381 1391
968   [네트웍/인터넷] IOCP(I/O Completion Port) class  김영대 2003/11/18 10414 798
967   [윈도우즈 API] 디렉토리나 파일의 속성(변경/생성/사용한 날짜, 특성) 바꾸기  김영대 2004/12/08 9654 1367
966   [데이터베이스] DBGrid의 Column, Record 의 위치 저장/이동  김영대 2003/03/04 8987 1381
965   [시스템] 델파이로 DOS 프로그램(Console application) 만들기  김영대 2003/03/06 8701 2828
964   [윈도우즈 API] 다른 프로그램에 마우스/키보드 이벤트 발생시키기  김영대 2004/09/07 7943 1294
963   [윈도우즈 API] URLDownloadToFile()를 사용한 파일 다운받기  김영대 2004/12/15 7885 1432
962   [시스템] 한글 한 음절을 초성,중성,종성 음소로 분해하기('김' => 'ㄱ'+'ㅣ'+'ㅁ')  김영대 2004/10/22 7786 1258
961   [윈도우즈 API] 실행 파일의 아이콘 바꾸기  김영대 2008/11/27 7728 1432
960   [COM/OLE] 탐색기에서 파일을 선택하여 ActiveX(ActiveFortm)에 Drag&Drop 하기  김영대 2005/01/06 7705 1303
959   [네트웍/인터넷] FTP로 디렉토리 목록(ls -l) 구하기  김영대 2004/10/09 7676 1362
958   [윈도우즈 API] 외부 프로그램 실행하기(ShellExecute) 정리  김영대 2003/03/05 7625 1413
957   [네트웍/인터넷] 윈도우즈 소켓의 에러번호에 대한 설명  김영대 2003/03/05 7600 2641
956   [일반/컴포넌트] RichEdit 2.0 줄간격 조정  김영대 2005/02/11 7598 1312
955   [네트웍/인터넷] HTTP의 다운받을 파일의 정보만 미리 읽어오기  김영대 2004/12/02 7562 1415
954   [네트웍/인터넷] RFC: Request for Comments  김영대 2003/03/05 7537 1977
953   [시스템] 2기가 이상의 하드의 남은 용량 알아내기...  김영대 2003/03/06 7394 2071
952   [시스템] '응답없음' 프로세서를 감지하는 잼나는 방법  구창민 2003/03/14 7322 1205
951   [시스템] 시스템의 각종 정보  김영대 2003/03/06 7244 1250
950   [시스템] 시스템 타임이 변경되었는지를 알아내려면...  김영대 2003/03/05 7242 2002
949   [시스템] 마우스의 좌/우 기능설정과 버튼갯수 알기  김영대 2003/03/06 7208 1958
948   [시스템] 시스템 대기모드/화면 보호기/모니터 끄기 이벤트 감지하기  김영대 2005/07/21 7193 1539
947   [일반/컴포넌트] 눌려진 키보드 키의 명칭 구하기  김영대 2003/03/07 7130 1373
946   [시스템] 인증서(certificate) 파일에서 직접 정보 읽어오기  김영대 2004/10/29 7096 1444
945   [네트웍/인터넷] Ethernet 랜카드의 MAC adress 구하기  김영대 2003/03/07 7080 1843
944   [윈도우즈 API] 작업표시줄의 시계 감추기/보이기  김영대 2003/03/27 7040 1921
943   [시스템] 윈도우즈 등록정보의 보안에 있는 권한 설정 변경하기(NT/2000/XP)  김영대 2004/09/25 7038 1539
942   [네트웍/인터넷] How to bring a network down - "Win Nuke"  김영대 2003/03/06 7028 1919
941   [네트웍/인터넷] List of raw FTP commands  김영대 2003/03/05 7021 1828
940   [네트웍/인터넷] NetMask 알아내기  김영대 2003/03/07 7002 1797
939   [일반/컴포넌트] 명령행 인자 받아오기  김영대 2003/03/05 6986 1821
938   [일반/컴포넌트] List of the Delphi 3 file types  김영대 2003/03/05 6934 1296
937   [일반/컴포넌트] 문자가 영문/숫자/영숫자/한글 인지 검사하기  김영대 2004/08/31 6796 1473
936   [네트웍/인터넷] 네트워크 공유 설정/공유 사용 권한/해제 하기 (Windows XP)  김영대 2004/11/09 6791 1352
935   [네트웍/인터넷] NT 네트워크 환경의 컴퓨터 리스트 구하기  김영대 2003/03/07 6787 1694
  [시스템] DOS 명령어 실행하고 실시간 결과 받아오기  김영대 2004/09/29 6732 1385
933   [일반/컴포넌트] Thread in a Timer  김영대 2003/04/07 6725 1066
932   [네트웍/인터넷] Ping 소스  김영대 2004/08/09 6723 1209

1 [2][3][4][5][6][7][8][9][10]..[25] [다음 10개]
 

Copyright 1999-2019 Zeroboard / skin by zero